But I suppose you don't want the sub missing() to be available as method the way ->foo() is?

That doesn't harm at all. Calling $obj->missing just returns false, which is correct :-)

However, your objection discovered a flaw in my approach. The missing sub needs to be prototyped to go one step further: multiple optional arguments. And then slurping starts hurting :-)

This leads to:

#!/usr/bin/perl

use v5.16;
use warnings FATAL => 'all';

package Foo;
use experimental 'signatures';
use constant MISSING => bless {}, __PACKAGE__ . '::__missing__';

sub missing :prototype(;$) {
    @_ ? $_[0] && $_[0] eq MISSING : MISSING;
}

sub new ($class) {
    bless {}, $class;
}

sub foo ($self, $foo=missing, $bar=missing) {
    say "foo is missing" if missing $foo;
    say "bar is missing" if missing $bar;
}

package main;

my $foo = Foo->new;
say "none:";
$foo->foo;
say "one:";
$foo->foo(1);
say "two:";
$foo->foo(1, 2);
print "\n";
say 'object foo is not missing' unless $foo->missing;

__DATA__
none:
foo is missing
bar is missing
one:
bar is missing
two:

object foo is not missing
[download]

> And then slurping starts hurting :-)

++ for linguistic excellency but not for correctness. ;-)

Some remarks:

• you don't need a sub missing() just compare with eq
• if you really need it make it a private sub with my $missing = sub {...}
• since constants are implemented as subs, they'll be methods too °
• slurping @vals can still handle both cases by checking the length
Anyway, you seem to be very convinced, so good luck and enjoy! :)

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}

°) maybe consider namespace::clean

Trying to implement it according to your remarks leads me to something I don't like at all.

EDIT: See comments in uglier_foo.

my $missing = sub {...};

# private sub
sub ugly_foo ($self, $foo=$missing->(), $bar=$missing->()) {
    say "foo is missing" if $missing->($foo);
    say "bar is missing" if $missing->($bar);
}

# compare with eq
sub uglier_foo($self, $foo=MISSING, $bar=MISSING) {
    # This comes from posting insufficiently tested code at midnight
    # say "foo is missing" if !$foo || $foo eq MISSING;
    # say "bar is missing" if !$foo || $foo eq MISSING;

    say "foo is missing" if $foo && $foo eq MISSING;
    say "bar is missing" if $bar && $bar eq MISSING;
}

# slurping
sub ugliest_foo ($self, @args) {
    my ($foo, $foo_missing);
    if (@args) {
         $foo = shift @args;
    } else {
        $foo_missing = 1;
    }
    my ($bar, $bar_missing);
    if (@args) {
        $bar = shift @args;
    } else {
        $bar_missing = 1;
    }
    if (@args) {
        croak "too many arguments";
    }
    say "foo is missing" if $foo_missing;
    say "bar is missing" if $bar_missing;
}
[download]

So, yes, I stubbornly stick to my solution.

Greetings,
-jo

$gryYup$d0ylprbpriprrYpkJl2xyl~rzg??P~5lp2hyl0p$