Firstly read perldsc then you can try this approach:

while reading the file, chomp the line, split the line using '| ' havi
+ng back col1 and col2 then push into the hash key col1 the value of c
+ol2. Hint: being values of the hash all arrayrefs you need some deref
+encing like in @{ $hash{ $col1 } } doing the push.
[download]

L*

Perhaps it is time to invest in a copy of The Perl Cookbook?

#!perl -aF/\|/ -n
use strict;
use warnings;

our %hash;
push @{$hash{$F[0]}}, $F[1];

END{
    use Data::Dumper;
    print Dumper(\%hash);
}
[download]

perl -MData::Dump -F"\|\s?" -lane "$.==1?next:push@{$h{eval$F[0]=~tr/\
+s//r}},$F[1]}{dd%h" columndata.txt

(
  500002,
  ["Network2"],
  500003,
  ["Network1", "Network3"],
  500001,
  ["Network1", "Network2"],
)
[download]

which deparsed gives:

perl -MO=Deparse -MData::Dump -F"\|\s?" -lane "$.==1?next:push@{$h{eva
+l$F[0]=~tr/\s//r}},$F[1]}{dd%h" columndata.txt

BEGIN { $/ = "\n"; $\ = "\n"; }
use Data::Dump;
LINE: while (defined($_ = readline ARGV)) {
    chomp $_;
    our @F = split(/\|\s?/, $_, 0);
    $. == 1 ? next : push(@{$h{eval $F[0] =~ tr/s//r};}, $F[1]);
}
{
    dd(%h);
}
-e syntax OK
[download]

L*

What Discipulus said:

Win8 Strawberry 5.8.9.5 (32)  Fri 05/14/2021  4:48:55
C:\@Work\Perl\monks\workInProgress12
>perl

use strict;
use warnings;
use autodie;

use Data::Dump qw(dd);

my $data = <<'EOD';
ColA | ColB |
     500001| Network1|
     500003| Network1|
     500002| Network2|
     500001| Network2|
     500003| Network3|
EOD

open my $fh, '<', \$data;

<$fh>;  # ignore headings record/line

my %hash4;

while (<$fh>) {

    my ($k, $v) =
        map { (my $r = $_) =~ s{ \A \s+ | \s+ \z }{}xmsg;  $r; }
        split /\s*\|\s*/  #splits $_ implicitly
        ;
  # print "\$k '$k'  \$v '$v' \n";  # for debug

    push @{ $hash4{$k} }, $v;

    }

dd \%hash4;

close $fh;

^Z
{
  500001 => ["Network1", "Network2"],
  500002 => ["Network2"],
  500003 => ["Network1", "Network3"],
}
[download]

Or with Text::CSV/Text::CSV_XS:

use warnings;
use strict;
use Data::Dump;
use Text::CSV; # also install Text::CSV_XS for speed

my %data;

my $csv = Text::CSV->new({ binary=>1, auto_diag=>2,
    sep_char=>"|", allow_whitespace=>1 });
my $hdr = $csv->getline(*DATA);
while ( my $row = $csv->getline(*DATA) ) {
    push @{ $data{ $row->[0] } }, $row->[1];
}
$csv->eof or $csv->error_diag;

dd \%data;

__DATA__
ColA | ColB |
     500001| Network1|      
     500001| Network2|
     500002| Network2|
     500003| Network1|      
     500003| Network3|
[download]

Hello Smart Monks, Thanks for your help. I have fixed this by below assignment

push @{ $hash4{$cellp[$_]} }, $cellr[$_] for (0..$#cellp);

I have fixed by below and lable as appropriate about within network or no network users

if (grep { grep { $_ eq "No Network" } @{$hash4{$celln[$o]}} } keys %h
+ash4) {
worksheet->write($r12, 2, "Non Network");
}
[download]

Thanks for your help.

> You really should know all this by now. (sigh)

why learning if he gets it for free? (sigh ;)

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}

True, true...

---

Give a man a fish:  <%-{-{-{-<

Hi,

By the pipe separator it looks like you are retrieving the data from a MySQL or other database. Is that the case? If so you can populate your hash of arrays while you are fetching the results from the DB.

while ( my $row = $sth->fetchrow_arrayref ) {
    push( @{ $hash{$row->[0]} }, $row->[1] );
}
[download]

Hope this helps!