They are identical in functionality. Where they differ is precedence. || and && have a higher precedence than and and or. Observe:

use warnings;
use strict;

my $one = 1;

$one += 0 || warn "||\n";
$one += 0 or warn "or\n";

$one += 0 && warn "&&\n";
$one += 0 and warn "and\n";
[download]

Output:

||
and
[download]

All examples attempt the same thing. Add $one to zero, which should obviously result in true (1). However, in the || example, instead of $one being added to zero, the || has a higher precedence than +=, meaning that the || binds to the zero before the addition-assignment happens, so the left hand side is false, therefore, the warn is executed. In the or line, the += has a higher precedence, meaning the left hand side is evaluated to true, so the warn is ignored.

It's similar for the && and and. && binds to the zero before the +=, so the left side is always going to be false, so the right side (warn) is never evaluated. With and, the addition happens first, then the and evaluation and because the LHS is true, the warn is executed.

Clear as mud? Good. Whenever you're using and or && || and you get results you don't expect, it's almost always related to precedence, especially in long convoluted evaluations where you're using negations and stuff.

Parens allow you to create your own precedence:

($one += 0) || warn "||\n";
[download]

There, whatever is in parens will be evaluated first before the || is brought into the mix. In this case, the || warning isn't thrown like it was above.

Maybe it's just me, but these things seem to be the same

They are the same in that regard, as the documentation you quoted says: "It's equivalent to && except for the very low precedence." The next section in the documentation, Logical or and Exclusive Or, explains why not, and, or, and xor are useful: for flow control. For example, if ( $x eq "x" ) { $y = "y" } can be written as $y = "y" if $x eq "x"; or $x eq "x" and $y = "y";, but not $x eq "x" && $y = "y";, because precedence messes that up. Another common place is open my $fh, '<', $filename or die "$filename: $!"; where || die would be wrong ("open" Best Practices), or for example I sometimes like to write if ( not ... ) {} instead of unless (...) {} because depending on the condition the former sometimes reads a little more easily.

They do the same except for precedence, i.e. for many other operations "op"

• A op B and C means (A op B) and C
• A op B && C means A op (B && C)

much the same way as

• 2 + 3 * 4 means 2 + ( 3 * 4 )

See https://perldoc.perl.org/perlop#Operator-Precedence-and-Associativity for more on "precedence"

updates

Deparsing (see O and B::Deparse) is a useful way to look at issues of precedence:

Win8 Strawberry 5.8.9.5 (32)  Mon 07/05/2021  1:12:59
C:\@Work\Perl\monks
>perl -Mstrict -Mwarnings -l -MO=Deparse,-p
my ($x, $y, $z) = qw(eks wye zee);

print $x && $y &&  $z;
print $x && $y and $z;  # $z is useless
^Z
Useless use of private variable in void context at - line 4.
BEGIN { $/ = "\n"; $\ = "\n"; }
use warnings;
use strict 'refs';
(my($x, $y, $z) = ('eks', 'wye', 'zee'));
print((($x && $y) && $z));
(print(($x && $y)) and $z);
- syntax OK
[download]

My stylistic advice on this topic: Re: Thoughts on using and, or, and not over && || !?

I agree in principle, but I tend to also use and and or in very complex expressions to be able to use less parens:

if (($foo && ($bar || $zebra) && ($fox & $mask) && $option_x) || ($zul
+y & $mask2 || $lion)) {
[download]

=>

if ($foo && ($bar || $zebra) && ($fox & $mask) && $option_x or $zuly &
+ $mask2 || $lion) {
[download]

most often with line breaks. The "or" and "and" will be bold in my editors syntax highlighting making it even more clear what the logical groups are. YMMV.


Enjoy, Have FUN! H.Merijn

Honestly, I find this still pretty unreadable.

Probably because it's a contrived example?

If this actually was realworld code I'd add many line-breaks and comments for each line.

Or even better break it down into speaking variables for sub-terms.

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}