There are a few ways to add (actually append in this case) one array to another, even if they are array references. A couple:

Win8 Strawberry 5.8.9.5 (32)  Mon 09/20/2021 15:47:19
C:\@Work\Perl\monks
>perl -Mstrict -Mwarnings

use Data::Dumper;

my $ar_1 = [ qw(knights who say ni) ];
my $ar_2 = [ qw(foo bar baz quux) ];

# push @$ar_1, @$ar_2;
$ar_1 = [ @$ar_1, @$ar_2 ];

print Dumper $ar_1;

^Z
$VAR1 = [
          'knights',
          'who',
          'say',
          'ni',
          'foo',
          'bar',
          'baz',
          'quux'
        ];
[download]

Update: As ++AnomalousMonk points out, my "solution" had the wrong sense on the compare! It should be ne instead of == just as he suggested.

I put the my original code into readmore brackets. The new code with one line of code + comments changed is below.

Note this brings up the issue of whether or not a duplication can occur of a record already in the $all array? see below.

 use strict;
use warnings;
use Data::Dump qw (pp);

my $accounts = [
    {
           'date' => '1980-03-05',
           'year' => '2019',
           'acc' => '44443',
         },
    {
           'date' => '1999-06-19',
           'year' => '2017',
           'acc' => '54321',
         },
    {
           'date' => '1999-09-19',
           'year' => '2099',
           'acc' => '12345',
         },
    ];
    
my $all = [
         {
           'date' => '2000-01-00',
           'year' => '2003',
           'acc' => '4327',
         },
         
         {
           'date' => '1987-01-03',
           'year' => '2013',
           'acc' => '89997',
         },
         
         {
           'date' => '1980-04-18',
           'year' => '2016',
           'acc' => '239876A',
         }, 
         
         {
           'date' => '1999-06-19',
           'year' => '2017',
           'acc' => '54321',
         }
        ]; 

# add all hashes from $accounts to $all,  but
# exclude account 44443, if it is there

foreach my $href (@$accounts)
{
     push @$all, $href if $href->{acc} ne '44443'; #note string compar
+e
} 

pp $all;
__END__

[
  { acc => 4327, date => "2000-01-00", year => 2003 },
  { acc => 89997, date => "1987-01-03", year => 2013 },
  { acc => "239876A", date => "1980-04-18", year => 2016 },
  { acc => 54321, date => "1999-06-19", year => 2017 },
  { acc => 54321, date => "1999-06-19", year => 2017 },
  { acc => 12345, date => "1999-09-19", year => 2099 },
]

Note: account OP's test $account data did contain a record that alread
+y
exists in the $all array. This results in a duplicate record.

See acc=> 54321 above.

There are of course ways to prevent that duplication.
Before suggesting code for that, I'd like to hear from the
OP whether this can really happen in "the real world" and
if such a solution is even needed.
[download]

It is perfectly ok for the input and the output of a grep to be the same array. Perl will keep it straight so that it doesn't "write over its own input".

# make the @$all array the union of everything in
# either @$all or @$accounts, excluding the acc 44443 record
# (if it exists at all) and exclude any possible duplicates
# This "zaps" the duplicate 54321 record.

# This literally says, "transfer the input to the output if
# the input record isn't about account 44443 and we haven't
# already transferred that record to the output before.  
# This assumes that records are uniquely id'ed by the acc
# number. That might or might not be true in the actual
# application.

my %seen;
@$all = grep{ $_->{acc} ne '44443' and !$seen{$_->{acc}}++ } @$all,@$a
+ccounts;
[download]

++Marshall for the post, but

• since an 'acc' value like '239876A' seems possible (per the OPed example), a string comparison should be used; and
• the OPed example wants records added to the output array if a particular key does not have a certain value, so ne should be used, e.g.,
      push @$all, $href if $href->{acc} ne '44443';
  (untested).

---

Give a man a fish:  <%-{-{-{-<

Thank you for pointing that out!++ I have updated my post. Your suggestion is exactly correct and I show actual run results.

Sorry for the goof! This issue just highlights the importance of showing "desired output" in the Original Post. If such a thing had existed, I would have detected this error myself.

I did see this alpha-numeric account number. And thought about things such as how to sort the @$all by account number. And now I see also either preventing or removing duplicate records for @$all might be necessary? However the OP is not asking about that at this time. Let's see what develops along that front, if anything.