# turn * into - within |...| regions
A |simple*example| is |so*simple| to come*up |with
these*days|

# turn * into - within |...| regions
A |simple-example| is |so-simple| to come*up |with
these-days|

use strict; 
use warnings;
use feature 'state'; 
            
use Test::More tests => 1;
            
my $in   = 'A |simple*example| is |so*simple| to come*up |with
these*days|';
my $want = 'A |simple-example| is |so-simple| to come*up |with
these-days|';   

my $have = join '|', 
    map { state $i = 0; $i++ % 2 and s/\*/-/g; $_ }
    split /\|/, $in, -1; 

is $have, $want;
[download]

---

🦛

that's very different because there are no lines in between.

use strict;
use warnings;
use Test::More;

my $in = 'A |simple*example| is |so*simple| to come*up |with
these*days| according to some *experts*';

my $exp = 'A |simple-example| is |so-simple| to come*up |with
these-days| according to some *experts*';

my $start = qr/\|/;
my $stop  = qr/\|/;

my $got = $in;

$got =~
s[
     ($start) (.*?) ($stop)
][
   "$1"
   . ( $2 =~ tr/\*/-/r )
   . "$3"
 ]gsxe;

is($got,$exp);

done_testing;
[download]

updates

added
• test
• line-break

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}

TIMTOWTDI

use strict;
use warnings;
use Test::More;

my $in = 'A |simple*example| is |so*simple| to come*up |with
these*days| according to some *experts*';

my $exp = 'A |simple-example| is |so-simple| to come*up |with
these-days| according to some *experts*';

my $start = qr/\|/;
my $stop  = qr/\|/;

my $got;

for ( split /($start|$stop)/s, $in) {
    if ( /$start/.../$stop/ ) {
        #print "<$_>";
        s/\*/-/gs;
    }
    $got .= $_;
}

is($got,$exp);

done_testing;
[download]

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}

> TIMTOWTDI

use strict;
use warnings;
use Test::More;

my $in = 'A |simple*example| is |so*simple| to come*up |with
these*days| according to some *experts*';

my $exp = 'A |simple-example| is |so-simple| to come*up |with
these-days| according to some *experts*';

my $start = qr/\|/;
my $stop  = qr/\|/;

my $got =
  join "",
  map { /$start/.../$stop/ ? s/\*/-/gr : $_ }
  split /($start|$stop)/s, $in;



is($got,$exp);

done_testing;
[download]

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}

The problem I see with SSCCE (despite its benefits) is that it encourages "particularization" instead of generalization; so after getting example-tailored responses, one has to play whack-a-mole with them to get to the original, abstract problem / "programming malaise".

Then again, those example-tailored responses always teach new bits of ingenuity. Anyway, thanks again.

The problem I see with SSCCE (despite its benefits) is that it encourages "particularization" instead of generalization ...

See How to ask better questions using Test::More and sample data. Is incumbent upon the question asker to provide a suitable coverage of test cases to meet their requirements.

---

🦛

> encourages "particularization" instead of generalization;

I like generalizations too.

I think the variations I showed are as general as possible and cover all use cases I could imagine.

Otherwise please provide an SSCCE ... ;-p

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}