use strict; 
use warnings;
use feature 'state'; 
            
use Test::More tests => 1;
            
my $in   = 'A |simple*example| is |so*simple| to come*up |with
these*days|';
my $want = 'A |simple-example| is |so-simple| to come*up |with
these-days|';   

my $have = join '|', 
    map { state $i = 0; $i++ % 2 and s/\*/-/g; $_ }
    split /\|/, $in, -1; 

is $have, $want;
[download]

use strict;
use warnings;
use Test::More;

my $in = 'A |simple*example| is |so*simple| to come*up |with
these*days| according to some *experts*';

my $exp = 'A |simple-example| is |so-simple| to come*up |with
these-days| according to some *experts*';

my $start = qr/\|/;
my $stop  = qr/\|/;

my $got = $in;

$got =~
s[
     ($start) (.*?) ($stop)
][
   "$1"
   . ( $2 =~ tr/\*/-/r )
   . "$3"
 ]gsxe;

is($got,$exp);

done_testing;
[download]

updates

• test
• line-break

use strict;
use warnings;
use Test::More;

my $in = 'A |simple*example| is |so*simple| to come*up |with
these*days| according to some *experts*';

my $exp = 'A |simple-example| is |so-simple| to come*up |with
these-days| according to some *experts*';

my $start = qr/\|/;
my $stop  = qr/\|/;

my $got;

for ( split /($start|$stop)/s, $in) {
    if ( /$start/.../$stop/ ) {
        #print "<$_>";
        s/\*/-/gs;
    }
    $got .= $_;
}

is($got,$exp);

done_testing;
[download]

> TIMTOWTDI

use strict;
use warnings;
use Test::More;

my $in = 'A |simple*example| is |so*simple| to come*up |with
these*days| according to some *experts*';

my $exp = 'A |simple-example| is |so-simple| to come*up |with
these-days| according to some *experts*';

my $start = qr/\|/;
my $stop  = qr/\|/;

my $got =
  join "",
  map { /$start/.../$stop/ ? s/\*/-/gr : $_ }
  split /($start|$stop)/s, $in;



is($got,$exp);

done_testing;
[download]

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}