in reply to How can I set a bit to 0 ?

G'day bartender1382,

"What I don't know how to do ... turn off a specific bit whether it is set or not."

Update: This wasn't a good solution (see reply below). The following would have been better: 

#!/usr/bin/env perl

use strict;
use warnings;

my $var1 = 0b00010100;
my $var2 = 0b00000110;

my $fmt = "%08b\n";

print "Initial:\n";
printf $fmt, $var1;
printf $fmt, $var2;

for my $bit (0, 1, 4) {
    print "Bit $bit off:\n";
    $var1 &= ~(1 << $bit);
    printf $fmt, $var1;
    $var2 &= ~(1 << $bit);
    printf $fmt, $var2;
}

[download]

I've stricken the original code; it's in the spoiler. The output is unchanged.

  1. Create a mask with the only bit set being the one you want to turn off.
  2. If number AND mask is true, then number XOR mask.

Here's some example code: 

#!/usr/bin/env perl

use strict;
use warnings;

my $var1 = 0b00010100;
my $var2 = 0b00000110;

my $fmt = "%08b\n";

print "Initial:\n";
printf $fmt, $var1;
printf $fmt, $var2;

for my $bit (0, 1, 4) {
    print "Bit $bit off:\n";
    $var1 = set_bit_off($bit, $var1);
    printf $fmt, $var1;
    $var2 = set_bit_off($bit, $var2);
    printf $fmt, $var2;
}

sub set_bit_off {
    my ($bit, $num) = @_;

    my $mask = 1 << $bit;

    $num ^= $mask if $num & $mask;

    return $num;
}

[download]

Output:

Initial:
00010100
00000110
Bit 0 off:
00010100
00000110
Bit 1 off:
00010100
00000100
Bit 4 off:
00000100
00000100

[download]

— Ken

Replies are listed 'Best First'.
Re^2: How can I set a bit to 0 ?
by GrandFather (Saint) on May 26, 2022 at 21:43 UTC

    Usually you are right on the money with excellent replies and advice. In this case you've missed by a country mile, especially in light of ikegami's excellent reply an hour earlier.

    Like stevieb, my experience writing embedded C++ firmware informs my familiarity with bit manipulation so I construct appropriate bit manipulation expressions almost without thought. The thought of using a sub to do what amounts to a handful of processor instructions even on RISC machines makes me shudder. I apologize for my reaction, but given the reply is from such an esteemed (at least by me) monk I felt the need to ensure the OP and other seekers of enlightenment shift their gaze to ikegami's reply.

    Optimising for fewest key strokes only makes sense transmitting to Pluto or beyond
[reply]
      I apologize for my reaction

      Most certainly not needed here, especially with the complete diligence and respect shown throughout the entire post (and all of your posts).

      I, for one, am in complete agreement with what you've said. ikegami's posts here and wide regarding bitwise operations show pure expertise, and, in fact, the software I posted about below was partly based on his posts here, and outside of this site.

[reply]

      G'day GrandFather,

      ++ Thanks for your thoughtful reply.

      I'll need to study this in more detail. I have an inkling of where I've cocked-up but I have to rush off to get my final Covid booster shot. I'll get back to this later today (side-effects permitting).

      — Ken

[reply]

        Hi Ken, it's not broken code, just sub-optimum technique. Bitwise operators are fundamental to most processors so they are generally very efficient at a processor level. In particular there should be no need for a test and conditional set (using xor or otherwise). There is a short comming with the code presented so far though. In the OP's context of setting flags in a bit set it's fine, but a common requirement is to update the value of a field of bits (1 to many adjacent bits). Again there is no need for a test. You just:

        use strict;
use warnings;

my $fieldIndex = 3;
my $fieldMask = 0b111 << $fieldIndex;

for my $fieldValue (0b000, 0b001, 0b100, 0b111) {
    my $fieldBits = $fieldMask & ($fieldValue << $fieldIndex);

    printf "With field value 0b%08b: \n   ", $fieldBits;

    for my $pattern (0x00, 0xff) {
        my $value = ($pattern & ~$fieldMask) | $fieldBits;

        printf "0b%08b --> 0b%08b   ", $pattern, $value;
    }

    print "\n";
}

        [download]

        Prints:

        With field value 0b00000000: 
   0b00000000 --> 0b00000000   0b11111111 --> 0b11000111   
With field value 0b00001000: 
   0b00000000 --> 0b00001000   0b11111111 --> 0b11001111   
With field value 0b00100000: 
   0b00000000 --> 0b00100000   0b11111111 --> 0b11100111   
With field value 0b00111000: 
   0b00000000 --> 0b00111000   0b11111111 --> 0b11111111

        [download]

        In this case the field is three bits wide (see $fieldMask). The important lines are the generation of $fieldBits which gets the field value in the right place and the generation of $value which inserts the field bits into the target bit pattern. This is bread and butter stuff in the embedded world, and is common when twiddling bit for things like network packets or in binary files.

        Optimising for fewest key strokes only makes sense transmitting to Pluto or beyond
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom