Single quotes do not interpolate.

In the $y example, you've got unbalanced quotes. The opener is a single quote, the end one is double. I'll bet you've mistyped the opening quote as single instead of double when you wrote this post.

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11153644
use warnings;
$SIG{__WARN__} = sub { die @_ };

my $cat = { dog => 'golden retriever' };

my $x='$cat->{dog}/mouse';
my $y=localtime();
$_=$x;
my $z = "$_:$y";
my $z2 = eval qq("$_:$y");

print "$z\n";
print "$z2\n";
[download]

Outputs:

$cat->{dog}/mouse:Mon Jul 31 12:36:50 2023
golden retriever/mouse:Mon Jul 31 12:36:50 2023
[download]

The first string literal uses single quotes. These don't interpolate.

The second string contains $_ and $y. Both were interpolated.

• $_ was replaced with its value, $cat->{dog}/mouse.
• $y was replaced with its value, Mon Jul 31 13:54:17 2023.

$x was read in from mysql and the value in it is not interpolated.

What I hear is that you stored incomplete Perl code (partial string literals) in the database as a template.

Some earlier posts show how to attempt to fix the incomplete Perl code (by adding double quotes) and how to execute that code (by using eval EXPR). But this isn't a good idea.

The better solution is to use a proper template system!

Can you help me understand what you mean by "a proper template system" and how to implement it in MYSQL? I know what a template is, not sure I'm familiar with the set of "proper" ones. TY

#!/usr/bin/env perl
use strict;
use warnings;
use Template;

my $from_db = q/Oh this year I'm off to Sunny [% country %]!
/;

my $tmpl = Template->new;

for my $dest (qw/Greece Italy Spain/) {
    $tmpl->process (\$from_db, { country => $dest });
}
[download]

$from_db is the immutable thing (the template) which you store in and retrieve from the DB. We then use Template to perform the required modifications. Template is one of the "proper" ones as you can find it listed in Task::Kensho. There are others, of course.

---

🦛

You're processing the template in Perl, not MySQL. Template-Toolkit is my go-to template system. The template would look like

[% cat.dog %]/mouse
[download]

instead of

$cat->{dog}/mouse
[download]

Alternate...

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11153644
use warnings;
$SIG{__WARN__} = sub { die @_ };

my $cat = { dog => 'golden retriever' };

my $x='$cat->{dog}/mouse';
$x = eval qq("$x");
my $y=localtime();
$_=$x;
my $z = "$_:$y";

print "$z\n";
[download]