%characters = map { $_ => $char++ } (
  'first character',
  'second character',
  'third character'
);
[download]

How do I define an anonymous hash using map?

$characters = { map { $_ => $char++ }
  'first character',
  'second character',
  'third character'
};
[download]

Thanks for the reply, jwkrahn! I'm still not sure how to work this into a charnames alias list, though. This:

#!/usr/bin/perl

use charnames ":alias" => { map { $_ => $char++ }
  'first character',
  'second character',
  'third character'
};

printf "First: %X; third: %X\n",
  ord("\N{first character}"),
  ord("\N{third character}");
[download]

produces the error:

Unknown charname 'first character' at ./mytest line 10, within string
Execution of ./mytest aborted due to compilation errors.
[download]

So it accepts the syntax of the alias setup, but doesn't actually create the aliases.

If you're suggesting I use your assignment statement as written and then use your $characters variable to do the alias setup, I can't even find the right syntax for that. This gives syntax errors on the use charnames line, as I would expect (as did a couple variants I tried):

#!/usr/bin/perl

$characters = { map { $_ => $char++ }
  'first character',
  'second character',
  'third character'
};

use charnames ":alias" => $characters;
[download]

Actually, there is a second issue besides constructing a literal anonymous hash, which is complicating your case.

It's the difference between run time vs compile time behavior.

use will execute at compile time, so does your construct. Any code you depend on to be run before must also be executed at compile time, like in a BEGIN block.

See perlmod for more on execution phases.

Update

And here a suggestion which seems best to be maintained IMHO.

(untested hack into mobile browser)

my %characters;

BEGIN {
    my $char = 0xE000;

    %characters = map { $_ => $char++ } (
      'first character',
      'second character',
      'third character'
    );
}

use charnames ":alias" => \%characters;
[download]

you may also consider putting your rather complicated specialized configuration array into a module of your own, which is executed with use

This will automatically happen at compile time, and provide you with a clean interface

Cheers Rolf
_{(addicted to the Perl Programming Language :)
see Wikisyntax for the Monastery}

Convert use charnames into BEGIN { ...; require charnames; ... } to be able to use %hash as the value for :alias export tag ...

# cat custom-name.pl; perl custom-name.pl

use strict;
use warnings;
use Data::Dump qw[dump];

BEGIN
{
   my $char = ord( q[a] );
   my %hash = map { $_ => $char++ } qw[ aey bee ];
   print dump( %hash ), qq[\n];

   use v5.16;
   require charnames or die $@;
   charnames->import( q[:alias] => { %hash, q[cea] => $char } );
}

printf qq[aey: %s\ncea: %s\n],
   qq[\N{aey}],
   qq[\N{cea}]
   ;
("bee", 98, "aey", 97)
aey: a
cea: c
[download]

... thanks to the response at https://stackoverflow.com/a/63018246, found via search for "perl begin use require export" as the documentation for use & require was inadequate.

Later I checked again & found use -- what I was really looking for (and realized MetaCPAN makes for a bad search engine for perl non-module documentation)!

Here's one way:

#!/usr/bin/perl

use strict;
use warnings;

my $char;
BEGIN { $char = 1; }

use charnames ":alias" => { map { $_ => $char++ } (
  'first character',
  'second character',
  'third character'
)};

printf "First: %X; third: %X\n",
  ord("\N{first character}"),
  ord("\N{third character}");
[download]

Note: Using 0 as a value for $char didn't work.

Hope this helps!

update: fixed typo

I have somehow never needed a BEGIN block (or any of perl's named blocks) before, so it never would have occurred to me to even search there

In case it further helps your general understanding of BEGIN blocks in Perl, I've listed a few more references below:

• use (perldoc)
• perlfaq8 (perldoc) - What's the difference between require and use?
• BEGIN, UNITCHECK, CHECK, INIT and END (perldoc)
• BEGIN block - running code during compilation (Perl Maven)
• How to write a require statement in perl to get the export tags from a module (SO)
• What is the role of the BEGIN block in Perl (SO) - typical usage is to make changes that affect subsequent compilation
• BEGIN blocks in awk - historically, Perl borrowed BEGIN blocks from the earlier AWK programming language, as noted in reply by perlfan

Note that a use Module qw/a b c/; statement is equivalent to:

BEGIN {
   require Module;
   Module->import(qw/a b c/);
}

while sub name {...} is equivalent to:

BEGIN {
   *name = sub {...};
}

update: but see response by ikegami for how to name the BEGIN block anon sub (useful in traces).

PM References Added Later

• Understanding use and require fully (2008)
• "use" vs "require" (2006)
• BEGIN block (2015)
• create an anonymous hash using "map" (2024)
• Use of BEGIN block (2025)

👁️🍾👍🦟

The practical uses of BEGIN and END in Perl may be more apparent when you consider how these were first used in awk. Perl of course took that idea and ran with it. As a Perl programmer, understanding this part of awk helped, especially with one-liners.

Nit: sub name {...} is almost equivalent to BEGIN { *name = sub {...}; }. The latter has no name associated with it, which matters in traces.

$ perl -e'
   use Carp qw( croak );
   sub foo { croak "bar" }
   foo();
'
bar at -e line 3.
        main::foo() called at -e line 4
[download]

$ perl -e'
   use Carp qw( croak );
   BEGIN { *foo = sub { croak "bar" }; }
   foo();
'
bar at -e line 3.
        main::__ANON__() called at -e line 4
[download]

There are ways of naming the anon sub to get a BEGIN-using equivalent.

$ perl -e'
   use Carp qw( croak );
   use Sub::Util qw( set_subname );
   BEGIN { *foo = set_subname "foo", sub { croak "bar" }; }
   foo();
'
bar at -e line 4.
        main::foo() called at -e line 5
[download]