use warnings;
use strict;

while (<DATA>) {
    print if /thing1/ or /thing2/;
}

__DATA__
thing1
foo
bar
thing2
thing1 and thing2
[download]

prints:

thing1
thing2
thing1 and thing2
[download]

Tried that, didn't work. Ok so lets say my text file has the following sentences

Transformers robots in disguise
I whip my hair back and forth
I will catch a dog with a trap
[download]

Now lets say, ignoring the case, the first word i want to look for is Trap, and the second word i want to look for is Hair. Basically it should print

I will catch a dog with a trap
i whip my hair back and forth
[download]

Is that more clear? Sorry for not making it clear before.

It seems to me that the problem is not that you want to detect both strings, but that you want to print them in the order of precedence, even if that's not the order in which they appear in the file. So you already know what order you want; you want to see "trap" first, and "hair" second. But they appear in the file in such order that "hair" comes before "trap".

This means you should not print immediately upon finding a match. Instead, you should accumulate your matches, and then print them in the order of relevance or importance.

Is that what you're after? If so, let us know.

Update: Here's one way you can do that. We maintain a list of triggers in some order of precedence. We also construct a list of matches. Then we run through the matches in trigger-list-order, printing them out. If there are two lines that trip the same trigger, they will be printed in the order they were seen, but otherwise we maintain trigger order rather than file order. I think that's what you were looking for:

use strict;
use warnings;

my @order = qw( trap hair );
my %found;
my $search = join '|', @order;

while( <DATA> ) {
  if( m/($search)/i ) {
    chomp;
    push @{$found{lc $1}}, $_;
  }
}

foreach my $wanted ( @order ) {
  if( exists $found{$wanted} ) {
    print "$_\n" for @{$found{$wanted}};
  }
}

__DATA__
Transformers robots in disguise
I whip my hair back and forth
I will catch a dog with a trap
[download]

The output:

I will catch a dog with a trap
I whip my hair back and forth
[download]

As you can see, the output comes in the order that you set in @order. If there had been two lines that match the same trigger, however, those lines would maintain file-order. So first priority goes to trigger order, and then within trigger order, file order takes second priority.




Dave

I'm not sure which question you are asking, but think you are looking for the flip-flop operator

try

open my $text, "<", $textFile>" or die "Dead";
while(<$text>){
   if(/$firstString/ .. /$secondString/){
      print $_;
   }
}
[download]

otherwise please show desired input and output.

Ok so lets say my text file has the following sentences

Transformers robots in disguise
I whip my hair back and forth
I will catch a dog with a trap
[download]

Now lets say, ignoring the case, the first word i want to look for is Trap, and the second word i want to look for is Hair. Basically it should print

I will catch a dog with a trap
i whip my hair back and forth
[download]

Is that more clear? Sorry for not making it clear before.

> Is that more clear?

no because your code should already do this, if you don't want double matches follow toolic's advice.

Cheers Rolf

PS: Je suis Charlie!

use strict;
use warnings;

my ($textFile, $firstString, $secondString) = @ARGV;

open my $text, "<$textFile" or die "Dead";

while(<$text>){
    if(/$firstString/m){
        print $_;
    }
    if(/$secondString/m){
        print $_;
    }
}
[download]

$ perl foo.pl foo.pl first second
my ($textFile, $firstString, $secondString) = @ARGV;
my ($textFile, $firstString, $secondString) = @ARGV;
    if(/$firstString/m){
    if(/$secondString/m){
[download]

I'm sorry, i accidentely put the closing brace. its not there, and unfortunately, doesn't work for me.

Download (do not retype or cut/paste) the examples from toolic Re: Multiple strings in a file and hotpelmen Re: Multiple strings in a file. Execute them as they describe. Post your results. The phrase "doesn't work" is not helpful.
Bill

use Modern::Perl qw /2014/;
use Data::Dump qw /dump/;

my @searchstrings = qw/trap hair dog I/;
my @found;

while (<DATA>) {
    while ( my ( $index, $search ) = each @searchstrings ) {
        push @{ $found[$index] }, [ $search, $., $_ ] if /$search/;
    }
}

say dump(@found);

__DATA__
Transformers robots in disguise
I whip my hair back and forth
I will catch a dog with a trap
[download]

(
  [["trap", 3, "I will catch a dog with a trap\n"]],
  [["hair", 2, "I whip my hair back and forth\n"]],
  [["dog", 3, "I will catch a dog with a trap\n"]],
  [
    ["I", 2, "I whip my hair back and forth\n"],
    ["I", 3, "I will catch a dog with a trap\n"],
  ],
)
[download]

open my $text, "<$textFile>" or die "Dead";
[download]

open my $text, '<', $textFile or die "Dead because: $!";
[download]