Hello bmcquill,

In addition to the references given above by GotToBTru, please see How-do-I-traverse-a-directory-tree of perlfaq5, and note that the module File::Find::Closures has a find_by_regex() method. For example (adapting the regex given above by aaron_baugher):

#! perl
use strict;
use warnings;
use Data::Dump;
use File::Find;
use File::Find::Closures 'find_by_regex';

my ($wanted, $list_reporter) = find_by_regex( qr{ ^ messages (?:\.\d+)
+? $ }x );
my  @directories = ('test');

File::Find::find($wanted, @directories);

my  @files = $list_reporter->();
dd \@files;
[download]

Output:

13:18 >perl 1226_SoPW.pl
["test\\messages", "test\\messages.1", "test\\messages.345"]

13:19 >
[download]

Hope that helps,

If I understand your requirements, you mean:

# Should match:
messages
messages.1
messages.345
# should not match:
messages.txt
messages.
messages123

If that's correct, I'll assume you know how to open a directory and read the files, so then inside that loop, just see if the filename matches the pattern you're looking for. This pattern looks for a filename starting with "messages" followed optionally by a . and any number of digits. The grouping parentheses around the dot and digits ensure that it will have both or neither.

if($filename =~ /^messages(\.\d+)?/ ){
  # this one matches
}
[download]

Interoperability note: Windows inherits from DOS -- filenames that end in dot are indistinguishable from filenames with no ending dot:

D:\PerlMonks>echo>message. This is a test.

D:\PerlMonks>dir

 Directory of D:\PerlMonks

04/22/2015  11:12 PM    <DIR>          .
04/22/2015  11:12 PM    <DIR>          ..
04/22/2015  11:12 PM                17 message

D:\PerlMonks>echo>message This is a test.

D:\PerlMonks>dir

 Directory of D:\PerlMonks

04/22/2015  11:12 PM    <DIR>          .
04/22/2015  11:12 PM    <DIR>          ..
04/22/2015  11:12 PM                17 message

D:\PerlMonks>echo>"message." This is a test.

D:\PerlMonks>dir

 Directory of D:\PerlMonks

04/22/2015  11:12 PM    <DIR>          .
04/22/2015  11:12 PM    <DIR>          ..
04/22/2015  11:12 PM                17 message

D:\PerlMonks>
[download]

The nit: Under Windows, message.and messageneed to be in the same category.

Hi, Aaron thanks that regex still returns everything. Any other ideas?

Add a $ to the end of aaron_baugher's expression, like this: /^messages(\.\d*)?$/. Also note the change of the + to a *

In case aaron_baugher has overestimated your skills ;) see Navigating and Reading Directories in the Tutorials section. Consider also glob.

all the files that begin with messages and MAY have a "." and a digit behind it, but it should not match something that has say .txt, .pl, etc.

Having a directory populated with these files

messages
messages.
messages.1
messages1.2.3
messages.1.gz
messages.2
messages.3
messages.pl
messages.txt
[download]

the following code

opendir D, '.';
while(readdir D) {
   /^messages(?:\.\d?)?$/ and print $_,"\n";
}
[download]

will output those:

messages.
messages.2
messages
messages.1
messages.3
[download]

The elements of that regular expression can be best explained using the x modifier (see perlre and perlfunc):

opendir D, '.';
while(readdir D) {
   m/            # begin of match
       ^         # match at the beginning of element, i.e. $_
       messages  # match 'messages' literally
       (         # begin of match group
        ?:       # subject to * ? +  not creating a capture
          \.     # match a period
          \d?    # optionally (?) match a digit
       )         # end of match group
       ?         # which may or not occur
       $         # before the end of the string
    /x           # tell m// that we use extended regex w/comments
    and          # if found
    print "$_\n" # print it out.
}
[download]

readdir is low level :) Path::Tiny is a whole nother level :P

use Path::Tiny qw/ path /;
print "$_\n" for path('.')->children( qr /^messages(?:\.\d?)?$/ ) ;
[download]

readdir is low level :) Path::Tiny is a whole nother level :P

That may well be, but is irrelevant for Regex for files.

perl -le'print map{pack c,($-++?1:13)+ord}split//,ESEL'

If you want to become a black-belt, read this book: http://www.amazon.com/Mastering-Regular-Expressions-Jeffrey-Friedl/dp/0596528124