use warnings;
use strict;
use List::Util qw(shuffle);

for ((shuffle(1..20))[0..9]) {
    print "$_\n";
}
[download]

Very concise and nice. Use library as much as possible.

Howdy, welcome to the Monastery!

There's many ways that this could be done. For one, you could check the "candidate" in your loop and get another one from rand if you already saw it before. In the following code, I'm using a hash (associative array) to remember which numbers were already seen:

my $x = 1;
my $y = 20;
my $looptimes = 10;

my %numbers = ();

foreach(1 .. $looptimes) {
    my $candidate = -1;

    do {
        $candidate = int(rand ($y - $x + 1)) + $x;
    } while(exists $numbers{$candidate});

    $numbers{$candidate} = 1;
}

say join ",", keys %numbers;
[download]

If you only care about the result, you could also e.g. take the list of numbers from $x to $y, shuffle it, and then grab the $looptimes numbers. How do I shuffle an array? has more on shuffling arrays; the executive summary is that there's a shuffle function in List::Util (a core module):

use List::Util qw/shuffle/;

my $x = 1;
my $y = 20;
my $looptimes = 10;

my @numbers = shuffle($x .. $y);

say join ",", @numbers[0 .. ($looptimes - 1)];
[download]

Though that said I reckon you care more about the "how" than the result.

Since you're starting out, here's a few general suggestions, too.

• use strict, and use warnings. They're your friends, and will catch many common mistakes, typos etc. for you.
• Format your code. Indent loop bodies and other blocks. Add spaces around the equal signs in assignments.
• Use for or foreach loops (exactly the same, BTW) to do something a given number of times; while loops are more appropriate when you don't know how often something'll have to be done.

Hope this helps!

 DB<109> %seen=();

 DB<110> $seen{int rand 10000}=1 while (keys %seen <10)

 DB<111> keys %seen
 => (4402, 3312, 9339, 1345, 3461, 9357, 1185, 4646, 6571, 1315)
[download]

Welcome deelinux

And another way of doing what you need:

      use strict;
      use warnings;
   
      my $x = 1; my $y = 20; my $looptimes = 10;
      my %NoDups = ();
   
      while( 1 )
      {   my $num = int( 1 + rand( 19 ) );
          if ( exists $NoDups{ $num } ) { next; }
          $NoDups{ $num } = 1;
          if ( keys %NoDups >= $looptimes ) { last; }
      }
   
      foreach my $no ( sort {$a<=>$b} keys %NoDups )
      {   print "$no\n"; }
[download]

Good Luck...Ed

I don't think it really matters if the value for a particular number is more than one so the exists test is perhaps overkill. The keys count is what matters.

$ perl -Mstrict -Mwarnings -E '
my %numbers;
$numbers{ int( rand 20 ) + 1 } ++
   while keys %numbers < 10;
say for sort { $a <=> $b } keys %numbers;'
4
7
8
9
11
13
14
15
17
18
$
[download]

I hope this is of interest.

Cheers,

JohnGG

The OP stated:

"...but every now and then I get duplicates in the list. I would like to remove the duplicates or not get one in the first place."

How do you define 'duplicates'?

Regards...Ed

"Well done is better than well said." - Benjamin Franklin

Heh, the algorithmically optimal (IMHO) way to get N unique numbers from a set of M of them is not actually covered in any of the replies. Not that this means you shouldn't use any of those solutions. I just think the method should be mentioned.

The process is the same as that used in List::Util's shuffle(), the Fisher-Yates Shuffle, except you stop early.

sub tenOf20 {
    my @set = 1..20;
    for( 0..9 ) {
        my $r = $_ + int( rand(@set-$_) );
        @set[$_,$r] = @set[$r,$_]
            if  $r != $_;
    }
    return @set[0..9];
}
[download]

Dear johngg and dsheroh,

I do not usually critique the answers of other monks ( unless I think it is wrong :-), since thanks to Perl we have many ways of doing the same thing. When I stated 'OP', I was referring to:

OP  Original Poster  The author of the top level node
                     of the thread in which it appears.
[download]

As for my use of 'exists', I benchmarked on Perl 5.12.2 that 'exists' was faster at checking keys than working on the values of the keys ( $h{$key}++; ). In johngg script, the way he uses the incrementing in his script, it may be faster.

Let's not have a flame war over my mis-understanding!

Best Regards...Ed

Hello all, many thanks for all the replies, code and advise, much appreciated!, I now need to digest, and play with your all your recommendations. Dee