With inheritance, there's no need to wrap the FFMech object in an EventRepository object - each EventRepository object already is a FFMech object, too.

The gets method seems to belong to EventRepository, not to FFMech: the nested _mech doesn't exist in the former class. With delegation, you'd define a get method in the FFMech class that would call $self->{_mech}->get, and in the EventRepository, you'd do the same: but its get would call FFMech's get, which in turn would call the original 'get'.

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,
[download]

I'm not sure I follow. I removed the EventRepository object out of the code just to try to simplify things:

my $ffm = FFMech->new;
$ffm->gets('http://nyt.com');
[download]

This results in an error:

Can't use an undefined value as a HASH reference at /usr/local/share/p
+erl/5.20.2/WWW/Mechanize/Firefox.pm line 804.
[download]

The gets() method in FFMech looks like this now:

sub gets {
  my $self = shift;
  my ($url, $sec, $syn) = set_args(@_);
  $self->get($url);
  sleep($sec);
}
[download]

$PM = "Perl Monk's";
$MCF = "Most Clueless Friar Abbot Bishop Pontiff Deacon";
$nysus = $PM . $MCF;
Click here if you love Perl Monks

I think you have your question backwards. You really want to call superclass methods.

You're conflating two OO idioms - inheritance (what you're derived from - in perl, we set @ISA, but better is base, and better yet is parent, and, depending on who you ask, there are better options available in Moose, Moo, and others), and composition (also known as "Has-A" - as in, FFMech Has A WWW::Mechanize::Firefox object). Don't do both for the same type.

You need to pick one. In general, if you want to expose nearly everything, maybe with a few tweaks, inheritance is easier. To set that up, you just use parent 'WWW::Mechanize::Firefox'; and you're mostly done. In your case, I see you have some extra defaults, so you can pass them on in your overridden new:

sub new {
  my ($class, %args) = @_;
  my $self = $class->SUPER::new(launch => 'firefox', activate => 1, %a
+rgs);
  $self->{_window_id} = FindWindowLike('Mozilla Firefox);
  ClickWindow($self->{_window_id});
  if ($self->title =~ /Restore Session/i) {
    $self->click( { selector => '#errorCancel' } );
  }
  return $self;
}
[download]

You'll notice that this no longer needs to call $self->{_mech} for getting to the mech object - because $self @ISA mech object, fully initialised!

For composition, you don't want to set up the @ISA relationship, so you don't set @ISA, call use parent or base or anything like that. Just use WWW::Mechanize::Firefox; to ensure it's loaded, and then you can create it in your constructor. However, then you have to redirect the interfaces you want to expose, e.g.:

sub get {
  my $self = shift;
  $self->{_mech}->get(@_);
}
[download]

for my $func (qw(get click ...)) {
  no strict 'refs';
  *$func = sub {
    my $self = shift;
    $self->{_mech}->$func(@_);
  };
}
[download]

use Moose;

has _mech => ( is => 'rw', handles => [ qw(get click ...) ] );
[download]

OK, I will noodle through this. Thanks. I'm using Daman Conway's old book from 2000 to get up to speed. I guess it's a bit obsolete because it doesn't mention "parent" and "base". Are there any more recent Perl OO books I should be looking at?

$PM = "Perl Monk's";
$MCF = "Most Clueless Friar Abbot Bishop Pontiff Deacon";
$nysus = $PM . $MCF;
Click here if you love Perl Monks

16 years is a long time in IT/CS. Conway's book is still worth absorbing though. This has some good stuff. I reach for Moo much faster than Moose but opinions differ and some monks think both are overkill/foolish. :P

For those interested in this problem, I settled on a solution (at least for now) using Moose. Thanks to everyone who offered suggestions and help. It was invaluable.