use warnings;
use strict;

my $pic = 1;
my $v = {R3R3_1_IF => 555};
my $key = "R3R3_${pic}_IF";
print "set groups interfaces $v->{$key}\n";

__END__

set groups interfaces 555
[download]

Thank you, toolic. It worked

I think increment of $pic is not happening with this method

 

my $pic = 1;
my $key_MS = "R3R3_${pic}_IF";
my $temp = 90;

          for (my $ip = 1; $ip<=100; $ip++) {
             if ($temp == $ip) {
             $pic++;
            }
        }
        print "New pic value is $key_MS\n";


output:New pic value is R3R3_1_IF
[download]

$pic is being incremented. This however has absolutely no effect on $key_MS which was set and evaluated when $pic was still 1. If you want to have it re-evaluated every time it is referenced you would need a closure or an eval or similar. eg. (with the loop replaced for clarity)

#!/usr/bin/env perl 
use strict;
use warnings;

my $pic = 1;
my $key_MS = sub { "R3R3_${pic}_IF"; };
print "Old pic value is " . &$key_MS . "\n";
$pic = 2;
print "New pic value is " . &$key_MS . "\n";
[download]

This seems like a parse error, but it's hard to say that the current behavior isn't intentional. Here are a few similar snippets, and how they deparse with -MO=Deparse,x9:

use strict;
use warnings;

my $pic = 1;
my $v = {R3R3_1_IF => 100};

print "Hello world. $v->{R3R3_$pic\_IF}\n";
[download]

The output with perl -MO=Deparse,x9 mytest.pl:

Backslash found where operator expected at mytest.pl line 9, near "$pi
+c\"
    (Missing operator before \?)
Bareword "_IF" not allowed while "strict subs" in use at mytest.pl lin
+e 9.
mytest.pl had compilation errors.
use warnings;
use strict;
my $pic = 1;
my $v = {'R3R3_1_IF', 100};
print "Hello world. $$v{$pic->R3R3_(\'_IF')}\n";
[download]

If you attempt to disambiguate using curly braces it still fails:

use strict;
use warnings;

my $pic = 1;
my $v = {R3R3_1_IF => 100};

print "Hello world. $v->{R3R3_${pic}_IF}\n";
[download]

The output...

Bareword found where operator expected at mytest.pl line 9, near "${pi
+c}_IF"
    (Missing operator before _IF?)
Bareword "_IF" not allowed while "strict subs" in use at mytest.pl lin
+e 9.
mytest.pl had compilation errors.
use warnings;
use strict;
my $pic = 1;
my $v = {'R3R3_1_IF', 100};
print "Hello world. $$v{$pic->R3R3_('_IF')}\n";
[download]

In both cases the interesting deparse to me is $pic->R3R3_('_IF'), and the explanation appears to be that the parser seems to feel this is a fine time to see the construct as indirect object notation.

I think I prefer toolic's computation of  $key as a separate step (more readable/maintainable), but if you really need it all in one statement:

c:\@Work\Perl>perl -wMstrict -le
"my $v = {
   R3R3_foo_IF => 'xyzzy',
   R3R3_bar_IF => 'wibble',
   };
 ;;
 my $pic = 'foo';
 ;;
 print qq{whatever $v->{ qq{R3R3_${pic}_IF} } and so on};
"
whatever xyzzy and so on
[download]

Update: The trick is to realize that  $v->{ qq{R3R3_${pic}_IF} } is really  $v->{ EXPR } where EXPR is any expression whatsoever (but not a statement). So  $v->{ qq{R3R3_${pic}_IF} } evaluates to a scalar which is double-quote-ishly interpolated as usual.

Try double-quoting the key: $v->{\"R3R3_$pic\_IF\"}.

update: I completely overlooked the outer quotes, so toolic's answer is the way to go to keep things clean.