You can use similar approach with almost any xml/html dom/tree module , you can skip the pretty printer if you're using a browser to view the results

#!/usr/bin/perl --
use strict;
use warnings;
use XML::LibXML;
use XML::LibXML::PrettyPrint;
my $html = q{<p> Looking for targets
<p> Text nodes to <i> bold </i>
<p> Inside <em> all kinds <i> of <a href="#tags"> tags </a></i></em>
<p> Maybe even <em><i>sep</i><u>a</u><i>rat</i><u>ed</u></em> in the f
+uture
<p> But <b targets="targets" bold="bold" tags="tags" separated="separa
+ted"> not </b> inside attributes 
};
my $xpp = XML::LibXML::PrettyPrint->new;
my $dom = XML::LibXML->new()->load_html( string => $html );
print $xpp->pretty_print( $dom );
hilite_text( $dom , 'target|bold|tags|separated' );
print $xpp->pretty_print( $dom );

sub hilite_text {
    my( $dom, $targets ) = @_;
    for my $text ( $dom->findnodes( '//text()' ) ){
        my( $before, $word , $after, ) = split /($targets)/, "$text";
        if( defined $word and length $word ){
            $before = $dom->createTextNode( $before );
            $after  = $dom->createTextNode( $after  );
            my $bold = $dom->createElement('b');
            $bold->appendText($word);
            $text->parentNode->replaceChild( $before, $text );
            $before->addSibling( $bold );
            $bold->addSibling( $after );
        }
    }
    return $dom;
}
[download]