I have fuzzy memory about backreferences in character classes. I recall hearing that they work in quite new versions of Perl and then being straightened out that they don't work and likely never will. That is, that [^\1] always matches any character but "\1" (CTRL-A, "\cA"). You seem to think that [^\2] works and I'm not trying to say you are wrong. Just that you might be wrong.

So, instead of [^\2] you might want (?!\2) (which wouldn't be the same if $2 were more than a single character).

Also, <[^<>]+> is better, otherwise:

Well, if < _$20_, you *need* <a href="...">this</a>
[download]

In a situation like this, I'd "tokenize" rather than "match":

use warnings;
use strict;

sub reg_fix {
    my $text = shift(@_);

    # I guessed what you wanted =equals= to indicate:
    my %tag= qw(  / em  * b  _ u  = strike  );

    my %open;
    @open{ qw( / * _ = ) }= ();

    my @tokens= $text =~ m{
      ( <[^<>]+>
      | [/*_=]
      | [^</*_=]+
      | <
      )
    }gmx;
    my @nested;

    for my $token (  @tokens  ) {
        if(  "<" eq $token  ) {
            $token= "&lt;";
        } elsif(  exists $open{$token}  ) {
            if(  ! defined $open{$token}  ) {
                $open{$token}= \$token;
                push @nested, $token;
            } else {
                ${$open{$token}}= "<$tag{$token}>";
                my $nest;
                do {
                    $nest= pop @nested;
                    undef $open{$nest};
                } while(  $nest ne $token  );
                $token= "</$tag{$token}>";
            }
        }
    }

    return join '', @tokens;
}

print reg_fix($_)   for  <DATA>;

__END__
go/to <img src='http://allpoetry.com:8080/images/smile/happy.gif'> /th
+x/ <img src='http://allpoetry.com:8080/images/smile/happy.gif'> _sill
+y *to_*
Well, if < _$20_, you *need* <a href="...">this</a>
[download]

go<em>to <img src='http://allpoetry.com:8080/images/smile/happy.gif'> 
+</em>thx/ <img src='http://allpoetry.com:8080/images/smile/happy.gif'
+> <u>silly *to</u>*
Well, if &lt; <u>$20</u>, you <b>need</b> <a href="...">this</a>
[download]

Note how I prevent mis-nesting of attributes.

You might see if something like Text::WikiFormat does what you want. Or if not it might give you something similar from which to work.

It handles nested tags (e.g., */stuff/*), but doesn't check for mis-nested tags like Tye's solution does.

Enjoy.

#!/usr/bin/perl -w
use strict;

my %sc = qw ( \\* b / em _ u );
my %counts;
my %opened;

sub track  {
    $opened{$_} = 1 - ( $opened{$_} || 0 );
    return "<$sc{$_}>" if --$counts{$_} > 0 && $opened{$_};
    return "</$sc{$_}>" if ! $opened{$_};
    $_;
}

sub reg_fix  {
    my $line=shift;
    %counts = (); %opened = ();
    $line =~ s/<([^>]*<)/\&lt;$1/g; # Replace unmatched < with &lt;
    my @elems = split '(<.*?>)', $line;
    $line =~ s/<.*?>//g;
    $counts{$_} = @{[$line =~ m/$_/g]} for keys %sc;
    for my $elem ( grep !/^</, @elems )  { $elem =~ s#$_#&track#eg for
+ keys %sc; }
    join '',@elems;
}

print reg_fix($_) for <DATA>

__DATA__
go/to <img src='http://allpoetry.com:8080/images/smile/happy.gif'> /th
+x/ <img src='http://allpoetry.com:8080/images/smile/happy.gif'> _sill
+y *to_*
Well, if < _$20_, you *need* <a href="...">this</a>
[download]

Which produces :

go<em>to <img src='http://allpoetry.com:8080/images/smile/happy.gif'> 
+</em>thx/ <img src='http://allpoetry.com:8080/images/smile/happy.gif'
+> <u>silly <b>to</u></b>
Well, if &lt; <u>$20</u>, you <b>need</b> <a href="...">this</a>
[download]

(Update - simplified code, egregious abuse of $_)