I tried to combine the second and fourth lines of the snippet,

You know that the start dir is going to be followed by a '\', so you could do $plsname =~ s/^\Q$startdir\E\\//i; and the fourth line becomes redundant.

You could combine the 5th line at the same time: $plsname =~ s[^\Q$startdir\E\\(.+)$][$1.pls]i

The /g on the third line makes that pretty much impossible to combine with the rest; and single character substitutions are better done with tr/// giving:

my $plsname = $curdir;

$plsname =~ s[^\Q$startdir\E\\(.+)$][$1.pls]i;

$plsname =~ tr[\\][_]; 

print $plsname;;
Schubert_Lieder_Terfel.pls
[download]

Is that better? Your call.

I'm not following your order, which may be a mistake, but anyway... "The /g on the third line makes that pretty much impossible to combine" is exactly the sort of guidance I was hoping to get.

"single character substitutions are better done with tr///" is not something I have seen documented anywhere. Is this a question of experience, or something I should have found for myself?

When I tried to sort out the backslash following the variable, I think I was trying to put it within the \Q\E part. Is this even possible? Things line \Q\E, quotemeta and qr are an area where my searches have been pretty fruitless. Are they identical? Are there any good docs on them?

A point on which I was expecting correction was another construct I tried to use without success. I have seen (and cargo culted) something like my ($plsname) = $curdir =~ regex;. Would that just mean having different operations on the same number of lines, or is there a better reason why it would be inappropriate here?

Thanks for the help & regards,

John Davies

"single character substitutions are better done with tr///" is not something I have seen documented anywhere. Is this a question of experience, or something I should have found for myself?

Um. Not sure about how I first learned it; probably reading a post hereabouts along time ago.

The thing to note is that tr/// is dedicated to replacing single chars with other single chars; and builds a translation table at compile time. Ie. It does just that one thing and does all the preparations up front.

On the other hand, s/// does all kind of stuff and has to interpret both the input specifications and replacements at runtime; so it is less efficient for this purpose.

When I tried to sort out the backslash following the variable, I think I was trying to put it within the \Q\E part. Is this even possible?

Backslashes pretty much always have to be escaped -- you can get away with them unescaped in single quotes if they don't come in front of a '.

If you put \ inside: \Q\\E, the second backslash escapes the third and the E is just an ordinary E. If you do \Q\\\E, the backslash ends up doubled in the results.

Things line \Q\E, quotemeta and qr are an area where my searches have been pretty fruitless. Are they identical?

\Q\E do the same as quotemeta, but only to that subset of the string or search term to which they are applied.

qr// is a quite different animal that is documented in http://perldoc.perl.org/perlop.html#Regexp-Quote-Like-Operators; and is intended for building regex strings, but turns out not to be as useful as you'd think because what it builds get re-interpreted if you include it as part of a another qr// or m// or s///.

A point on which I was expecting correction was another construct I tried to use without success. I have seen (and cargo culted) something like my ($plsname) = $curdir =~ regex;

In the form you've posted that would assign (the first) capture group in the regex to $plsname; which isn't applicable here.

You could do ( my $plsname = $curdir ) =~ s/.../.../; which would do the assignment, then operated on the new variable; but it's much of a muchness.

I always find it hard to answer 'how would I have learnt that' questions, because I've long since forgotten when/how I learnt them.

---

With the rise and rise of 'Social' network sites: 'Computers are making people easier to use everyday'

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority". I knew I was on the right track :)

In the absence of evidence, opinion is indistinguishable from prejudice.

Further to some of BrowserUk's comments ++above:

• A  \ (backslash) within a  \Q...\E sequence: if the backslash is included in the interpolated variable, things are simpler:

  c:\@Work\Perl\monks>perl -wMstrict -le
  "my $curdir   = 'Y:\Music\Schubert\Lieder\Terfel';
   my $startdir = 'Y:\mUsIc\\';
   ;;
   my $plsname = $curdir;
   $plsname =~ s/^\Q$startdir\E//i;
   $plsname =~ s/\\/_/g;
   $plsname .= '.pls';
   print qq{'$plsname'};
  "
  'Schubert_Lieder_Terfel.pls'
  [download]

  (Note that the final  \ (backslash) in the  $startdir assignment has to be escaped because it's just before the closing single-quote delimiter.)
• Some examples of  my ($plsname) = $curdir =~ regex; (still not applicable):

  c:\@Work\Perl\monks>perl -wMstrict -le
  "my $s = 'bar foooo bozzle';
   ;;
   my ($capture) = $s =~ m{ (fo+) }xms;
   print qq{'$capture'};
   ;;
   my ($found_it) = $s =~ m{ (?<= \s) b .* e }xmsg;
   print qq{'$found_it'};
   ;;
   my $regex = qr{ \A (b \w+) }xms;
   my ($it_was_there) = $s =~ $regex;
   print qq{'$it_was_there'};
  "
  'foooo'
  'bozzle'
  'bar'
  [download]

  (The second example without explicit capture groups.) (Update: Changed code above to add  $regex example.)
• Also note that BrowserUk is very experienced at dealing with Big Data. If you're operating on a single string of a few dozen/hundred/thousand characters, the difference between  s///g and  tr/// will not be detectable | noticeable in practice.
• As to docs, all the usual suspects: perlre, perlretut, perlrequick, perlrecharclass, perluniprops; in perlop: Quote and Quote-like Operators, Regexp Quote-Like Operators, Quote-Like Operators. (Update: Also see Pattern Matching, Regular Expressions, and Parsing in our very own Tutorials.)

---

Give a man a fish:  <%-{-{-{-<

"single character substitutions are better done with tr///" is not something I have seen documented anywhere. Is this a question of experience, or something I should have found for myself?

Just adding on to BrowserUk's comments re: tr. Another big factor is that tr doesn't have to worry about the string getting longer! You can't substitute one character with 2 others. But that means that tr doesn't have any memory allocation worries (getting shorter is a whole different deal than getting longer). The net result of all of these simplifications means that tr runs like a rocket.

Update: This thread about tr got me thinking... I volunteer as a TA for a MASM (Microsoft Assembly) class at a local college. We are always thinking of new labs. A "tr" lab is likely to appear in the Fall 2016! The C version of tr is fast, the assembly language version will be really, really fast. And we can teach some other stuff along the way. Quoting my prof for the suggestion of a tr lab:

Implementing tr is a good exercise! It makes use of the optimized array instructions and it reinforces the idea that characters are just integers, which, as you recall from the last ASM class, some students had a hard time converting a digit to its ASCII character. Thanks!

Sometimes these Perl questions spawn other thoughts. Have no doubt that tr can be implemented very efficiently in ASM class 101. That is definitely not true of regex!

I didn't think the OPed code was really so terrible to begin with (once the  $plsname =~ s/\//_/g; statement is fixed). But in an attempt to "one-liner-ize" the code, and building on BrowserUk's post (and using my preferred regex practices), here's this:

c:\@Work\Perl\monks>perl -wMstrict -le
"my $curdir   = 'Y:\Music\Schubert\Lieder\Terfel';
 my $startdir = 'Y:\mUsIc';
 ;;
 my $plsname = $curdir;
 $plsname =~ s{ \A (?i) \Q$startdir\E \\ (.+) \z }
              { (my $r = $1) =~ tr{\\}{_};  $r . '.pls'; }xmse;
 print qq{'$plsname'};
"
'Schubert_Lieder_Terfel.pls'
[download]

If you have Perl version 5.14+, it's possible to slightly simplify the  s/// replacement executable code above to
    $1 =~ tr{\\}{_}r . '.pls';
and in fact you could go all the way to

c:\@Work\Perl\monks>perl -wMstrict -le
"my $curdir   = 'Y:\Music\Schubert\Lieder\Terfel';
 my $startdir = 'Y:\mUsIc';
 ;;
 my $plsname =
   $curdir =~ s{ \A (?i) \Q$startdir\E \\? }{}xmsr =~ tr{\\}{_}r . '.p
+ls';
 print qq{'$plsname'};
"
'Schubert_Lieder_Terfel.pls'
[download]

Update: For info on the  /r modifier added in Perl version 5.14, see  s/// in Regexp Quote-Like Operators and  tr/// in Quote-Like Operators, both in perlop.

Much reading later - and thank you for all the references in your other post, only some of which I had read previously - I think I understand what you are doing. I do have some questions, though. Am I right in thinking that the (?i) has the same effect as an i qualifier with xmsr? If not, what is the difference (and where is it documented, please)? If so, and I appreciate that you have stated "my own preferred practices" which exempts you from needing a reason, is there a reason why you prefer to have the qualifiers separately?

How come none of the spaces in { \A (?i) \Q$startdir\E \\? } are treated as matchable characters? I suspect it's one of your qualifiers, but I couldn't find it explained in any of the docs I read, unless it's part of x, and I haven't looked for the documentation for that beyond reading that it means "extended regexes".

I find your final assignment ($var = $var =~ regex =~ regex) rather confusing, as it seems to need to work from left to right at some times and from right to left at others. I know things joining things like map, grep & sort result in the expression working right to left. I don't remember seeing three assignment-like = signs in a Perl statement before, which may be part of my confusion. Is the order irrelevant, and if not, what are the rules for the direction of evaluation?

Thanks and regards,

John Davies

Am I right in thinking that the (?i) has the same effect as an i qualifier with xmsr?

Yes — almost. In, e.g.,  s{ ... }{...}xmsi the  /i modifier affects the regex match globally. A  (?i) extended pattern only has effect from the point of its appearance in the regex to the end of the regex pattern scope — which may or may not be the end of the regex! (See Extended Patterns. I must apologize: I did not mention that extended patterns are only available from Perl version 5.10 onward; I assume you have this.) I prefer the embedded  (?i) form because it is more visible and because it gives more control: case sensitivity can be turned on and off at will in a regex, and its scope closely controlled. In general, "my own preferred practices" are that the  qr// operator has only the  /xms modifiers applied to the operator, and all other modifiers , e.g., (?i), scoped within the operator. This practice just generalizes to the  m//xms and  s///xms operators. The latter two operators can also take  /g /e /r modifiers which can only be applied to the operator as a whole.

... none of the spaces in { ... } are treated as matchable characters? I suspect it's ... x ...

Yes, exactly. Allowing whitespace not to be part of the pattern eases the strain on these old eyes, a great blessing after so many years toiling in the scriptorium. See  /x in Modifiers.

I find your final assignment ($var = $var =~ regex =~ regex) rather confusing, as it seems to need to work from left to right at some times and from right to left at others.

It might have been helpful if I had thrown in a few disambiguating parentheses. But you can always add your own with O and B::Deparse:
(Here I wanted to give an example of the deparsed code, but for some reason I don't understand, it didn't work out! Quickly moving on...)
Anyway, by hand:

c:\@Work\Perl\monks>perl -wMstrict -le
"my $curdir   = 'Y:\Music\Schubert\Lieder\Terfel';
 my $startdir = 'Y:\mUsIc';
 ;;
 my $plsname =
   ((($curdir =~ s{ \A (?i) \Q$startdir\E \\? }{}xmsr) =~ tr{\\}{_}r) 
+. '.pls');
 print qq{'$plsname'};
"
'Schubert_Lieder_Terfel.pls'
[download]

Working in order of precedence (more or less inside-out in this case):
1. ($curdir =~ s{ \A (?i) \Q$startdir\E \\? }{}xmsr)
   A substitution is done on  $curdir and the substituted string returned courtesy of the  /r modifier of 5.14+;
2. (($curdir =~ s{ ... }{}xmsr) =~ tr{\\}{_}r)
   The string returned by the  s///r substitution is operated upon by  tr///r and the translated string is returned;
3. ((($curdir =~ s{ ... }{}xmsr) =~ tr{\\}{_}r) . '.pls')
   The string  '.pls' is appended to the string returned by  tr///r and;
4. The whole thing is finally assigned to $plsname. Whew!

Is the order irrelevant, and if not, what are the rules for the direction of evaluation?

The order is very relevant, and is discussed in Operator Precedence and Associativity in perlop: see the  =~ (binding) and  . (concatenation) and  = (assignment) operators.

Update: Layout of  <ol> above changed – improved?

---

Give a man a fish:  <%-{-{-{-<

one possible way demonstrated under the Perl debugger:

  DB<1> $curdir = 'Y:\Music\Schubert\Lieder\Terfel';

  DB<2> $startdir = 'Y:\Music';

  DB<3> $curdir =~ s/^\Q$startdir\E\\//i;

  DB<4> $out = join "_", split /\\/, "$curdir.pls";

  DB<5> p $out;
Schubert_Lieder_Terfel.pls
[download]

You could even do it in a single code line:

  DB<7> $curdir = 'Y:\Music\Schubert\Lieder\Terfel';

  DB<7> $startdir = 'Y:\Music';

  DB<8> $out = join "_", map {s/^\Q$startdir\E\\//i;  split /\\/, "$_.
+pls"} $curdir ;

  DB<9> p $out
Schubert_Lieder_Terfel.pls
[download]

Hi davies,

One Way To Do It... without regexen ;-)

use Path::Class qw/file dir/;
my $startdir = dir('/Y/Music/');
my $curdir = dir('/Y/Music/Schubert/Lieder/Terfel');
my $plsname = join('_', grep {length}
    $curdir->relative($startdir)->components).".pls";
print "$plsname\n";

__END__

Schubert_Lieder_Terfel.pls
[download]

I used unixish paths but it works the same on Windows. The grep {length} may not be necessary, I just figured it was the closest equivalent to your s/^_?//;.

Path::Class::Dir also has functions for searching that can replace File::Find.

Hope this helps,
-- Hauke D

Yet another one-liner. This is a bit tricky, and I can't say I'm particularly proud of it. It assumes  $startdir always has a trailing  \ (backslash) delimiter. Needs Perl version 5.14+ for the  s/// substitution  /r modifier.

c:\@Work\Perl\monks>perl -wMstrict -le
"use 5.014;
 ;;
 my $curdir   = 'Y:\Music\Schubert\Lieder\Terfel';
 my $startdir = 'Y:\mUsIc\\';
 ;;
 my $plsname =
   $curdir =~ s{ \A (?i) \Q$startdir\E | \\ }{ $-[0] ? '_' : '' }xmsre
+g . '.pls';
 print qq{'$plsname'};
"
'Schubert_Lieder_Terfel.pls'
[download]

Update: Even more perverse, but requires no  /r modifier, so it can run under pre-5.14, and no  /e modifier:

c:\@Work\Perl\monks>perl -wMstrict -le
"print qq{perl version $]};
 ;;
 my $curdir   = 'Y:\Music\Schubert\Lieder\Terfel';
 my $startdir = 'Y:\mUsIc\\';
 ;;
 my %replace = ('1', '',  '-1', '_',  '0', '.pls');
 (my $plsname = $curdir) =~
   s{ \A (?i) \Q$startdir\E | \\ | \z }
    {$replace{ $-[0] == 0 || $-[0] <=> $+[0] }}xmsg;
 print qq{'$plsname'};
"
perl version 5.008009
'Schubert_Lieder_Terfel.pls'
[download]

Update 2: Ok, slightly simpler, but needs captures:

c:\@Work\Perl\monks>perl -wMstrict -le
"print qq{perl version $]};
 ;;
 my $curdir   = 'Y:\Music\Schubert\Lieder\Terfel';
 my $startdir = 'Y:\mUsIc\\';
 ;;
 my %replace = ('1', '',  '2', '_',  '3', '.pls');
 (my $plsname = $curdir) =~
   s{ (\A (?i) \Q$startdir\E) | (\\) | (\z) }
    {$replace{ $#- }}xmsg;
 print qq{'$plsname'};
"
perl version 5.008009
'Schubert_Lieder_Terfel.pls'
[download]