Test in small increments. For example to parse the SDF file, you could break out my code into a short test program like this:

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;


my %keepList;

while (my $line = <DATA>) 
{
   my $sdf_file;
   next unless ($sdf_file) = $line =~ /(\w+\.nfo)/;
   $keepList{$sdf_file} = 1;
   print "keeping $sdf_file\n"; #update for debugging #######
}

=example printout
keeping filename1.nfo
keeping filename2.nfo
=cut

__DATA__
fullpath="C:\directory\filename1.nfo"
id="1a"
fullpath="C:\directory\filename2.nfo"
[download]

update: I should clarify, when you have a choice, use only [a-zA-Z0-9_], in the file names, basically anything that meets the rules of a valid identifier in Perl or C is fine, what Perl calls \w characters. Forgo using spaces or dashes in the names if you can and your life will be easier.

Hi Marshall,

Thanks! That does work! With the help of my co-worker, we refined it a little more by including white spaces in search.

Thank you all who have helped me with my problem.

Below is what we came up with.

#!\perl\bin\perl

use strict;
use warnings;

my $files = "C:/Directory";
my $list = "C:/Test.sdf";

open my $name, '<', $list or die "Failed to open file: $!\n";

my @files = $files;
opendir(OUTPUT, $files);
  @files = grep {$_ ne '.' and $_ ne '..'} readdir(OUTPUT);
closedir(OUTPUT);

my %wanted_files;

while (<$name>) {
  if ($_ =~ /^\s*fullpath=.*[\\\/](\w+\.nfo)"/) {
    $wanted_files{$1} = 1;
  }
}

foreach my $target_file (@files) {
  if (not $wanted_files{$target_file}) {
    unlink($files . "/" . $target_file) or die $!;
  }
}
[download]

Did you actually test that your regex would deal with spaces in the file name? I think not. \w+ will not match a space, only [0-9a-zA-Z_]. A demo of different regex:

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;

my %keepList;

while (my $line = <DATA>) 
{
   my $sdf_file;
   next unless ($sdf_file) = $line =~ /([\w ]+\.nfo)/;
   $keepList{$sdf_file} = 1;
   print "keeping \"$sdf_file\"\n"; #update for debugging #######
}

=example printout
keeping "filename1.nfo"
keeping "filename2.nfo"
keeping "file name2.nfo"
keeping "file name3.nfo"
keeping "file   name4.nfo"
=cut

__DATA__
fullpath="C:\directory\filename1.nfo"
id="1a"
fullpath="C:\directory\filename2.nfo"
id = "nonsense"
fullpath = "C:\directory\file name2.nfo"
fullpath = "C:/directory/file name3.nfo"
fullpath = "C:\directory/file   name4.nfo"
[download]

Your code:

my @files = $files;
opendir(OUTPUT, $files);
  @files = grep {$_ ne '.' and $_ ne '..'} readdir(OUTPUT);
closedir(OUTPUT);
[download]

better written? as:

opendir(OUTPUT, $files) or die "unable to opendir $!";
my @files = grep {-f $files/$_} readdir(OUTPUT);
closedir(OUTPUT);
[download]

The -f file test excludes not only the "." and ".." directories but also other ones that might exist.
my @files = $files; does nothing useful.

Overall, great job at getting something to "work". In the scheme of things, my comments are just nits.