I don't know how perl pre-parses code on the fly - is it quicker (i.e. will perl map out a call to a sub-routine on pre-parse) such as

if ($debug == "true") {
&debugit;  # call the routine
}
[download]

or

if ($debug == "true") {
** do all the debug code here and/or carry on **
}
[download]

Premature optimization. Keep the code readable and maintainable. If you need the debug code more than once, put it in a function. If the debug code spans more than a few lines, do the same. For a single, simple print, wrap it directly in the if block.

Oh, and by the way: Omit the ampersand in function calls. It is perl4-style and does not do what you expect. See also Re^2: Merge log files causing Out of Memory (just a note on ampersand).

Another update: $debug == "true" does not do what you want. == is for numeric compares, eq is for string compares. (how to remember that). But you don't want either, use Perl's native booleans: In boolean context, scalars that are undefined (undef), the empty string ("") or the number zero (0) evaluate as false, any other value evaluates as false true. Commonly, you would use the value 1. So:

my $debug=1; # or $debug='' to disable
# later:
if ($debug) {
    debugIt();
}
[download]

Alexander

Blimey!, as we say here in England.

I just re-read about sub routines in my Camel book, and have never ever heard about omitting the & - just a 'subroutine();' does it!

I just changed my code to have a sub debug; and it works great and seems more fluid!

Many thanks for your wisdom!

Regards, Nick

P.S. sorry, was replying then saw your update - the '==' was a mistake by me just typing in from a bad memory - should be 'eq' of course!

Thanks again. The line '$debug eq "true"' is a must as it comes from a HTML form and can have different string values, so a match is needed.

Nick

I don't know how perl pre-parses code on the fly ...

You can let Perl tell you how it parses your code; see O and B::Deparse.

c:\@Work\Perl\monks>perl -wMstrict -MO=Deparse,-p -le
"use constant DEBUG => 1;
 ;;
 DEBUG and debugIt();
 ;;
 sub debugIt { print 'debugging it'; }
"
BEGIN { $^W = 1; }
BEGIN { $/ = "\n"; $\ = "\n"; }
use constant ('DEBUG', 1);
use strict 'refs';
debugIt();
sub debugIt {
    use strict 'refs';
    print('debugging it');
}
-e syntax OK

c:\@Work\Perl\monks>perl -wMstrict -MO=Deparse,-p -le
"use constant DEBUG => 0;
 ;;
 DEBUG and debugIt();
 ;;
 sub debugIt { print 'debugging it'; }
"
BEGIN { $^W = 1; }
BEGIN { $/ = "\n"; $\ = "\n"; }
use constant ('DEBUG', 0);
use strict 'refs';
'???';
sub debugIt {
    use strict 'refs';
    print('debugging it');
}
-e syntax OK
[download]

Update:
    if (DEBUG) { debugIt(); }
and
    debugIt() if DEBUG;
would be other variations you might use. Of course, prefer
    if (DEBUG) { more(); than(); one(); statement(); }
for, well, more than one statement.

use constant DEBUG => 1;
do_debug() if DEBUG;
[download]

So, in the context of your post, there can't be anything faster than doing nothing at all in the non-debug case. Also often in my debug code, usually some sort of I/O operation is going to happen which is so slow that whether it is in a subroutine or not makes absolutely no difference in the scheme of things.

update: Usually instead of just "do_debug()", I put some name on that subroutine like perhaps "dump_decision_tree() if DEBUG;". I do that even if this debug code could only be called once. The name of the sub tells me what it would do without having to look further. I don't have to skip past "inline" debug code. I usually do that for anything more than a simple "print".

OK, thanks all. After enlightenment I have found a decent solution

As the requirement comes from an HTML form (returns '1' if ticked), the code I am now using to call the function is thus:

debug() if $request{'debug'};
[download]

Short and sweet :)

Nick