Assuming the Activity code is unique within the data, and you want to preserve the column order and the record order try this ;

#!perl
use strict;
use Data::Dumper;

my $actid;
my $key;
my $last;
my $colno = 0;
my @order = ();
my %cols  = ();
my %data  = ();

#my $infile = 'data.txt';
#open IN,'<',$infile or die "$!";
while (<DATA>){ #or IN
  chomp;
  next unless /\S/; # skip blank lines
  
  # continuation line
  if (! /:/){
    $data{$actid}{$key} .= $_;
    next;
  }
  
  ($key,my $value)= split ':',$_,2;

  # create unique phone column
  if ($key eq 'Phone'){
    $key = $last.' '.$key
  }
  $last = $key;

  if ( $key eq 'Activity' ){
    $actid = $value;
    push @order,$actid;
  } 
  $cols{$key} = ++$colno unless exists $cols{$key};
  $data{$actid}{$key} = $value;
}
# close IN;
print Dumper \%data;
print Dumper \%cols;

# output
use Text::CSV;
my $csv = Text::CSV->new ( 
    { binary => 1 ,
      eol    => "\n",
    } )
  or die "Cannot use CSV: ".Text::CSV->error_diag ();
  
# col headings  
my @header = sort { $cols{$a} <=> $cols{$b} } keys %cols;
print Dumper \@header;
$csv->column_names(@header); 

# ouput records
open my $fh, '>', "new.csv" or die "new.csv: $!";
$csv->print($fh,\@header);
for my $actid (@order){
  $csv->print_hr($fh, $data{$actid});
}
close $fh or die "new.csv: $!";

__DATA__
Activity:C2012-0109
Type:COMBO
..
[download]

Update : ++GotToBTru for duplicate phone columns

This is amazing! Thank you!

In general, this kind of problem is very easy to solve in Perl, but your data poses a few problems.

1. You have multiple columns with the same name
2. You have commas in your data

use strict;
use warnings;

chomp(my $datafile = shift || 'data.file');
my $outputfile = 'output.file';
my @keys_in_display_order = qw/Activity Status Valuation/;
my (%hash);

open my $ifh, '<', $datafile;
open my $ofh, '>', $outputfile;

printf $ofh "%s\n", join '|', @keys_in_display_order;

while(<$ifh>) {
  next unless $_;
  if (/^$keys_in_display_order[0]/) {
    print_it();
    %hash = ();
  }
  $hash{$1} = $2 if (m/(.+):(.+)$/);
}
print_it();

close $ifh;
close $ofh;

sub print_it {
  return unless (%hash);
  printf $ofh "%s\n", join '|', @hash{@keys_in_display_order};
}
[download]

cat output.file
Activity|Status|Valuation
C2012-0106|ISSUED|$339,784.94
C2012-0107|ISSUED|$306,963.74
[download]

Hello chimiXchanga,

Maybe this could help (Parsing text file to CSV)

Update: Similar question(s) that might help you: (creating hash of hashes from input file)

Update 2: I also found: Text::Table that might help you to get the desired output before print into a CSV file, here is also a tutorial about it Text::Table Tutorial.

Hope this helps.