Hello iatros, and welcome to the Monastery!

Each element of a hash (or of an array, for that matter) must be a scalar value. So if you want to store an array of values in the points slot of a hash, you have to store a pointer to that array:

$student = {
    ...
    points => \@points,
};
[download]

or

$student = {
    ...
    points => [@points],
};
[download]

See perlreftut and perldsc.

Update: To elaborate on stevieb’s point: if the array @points contains the elements ('a', 'b', 'c', 'd'), then the assignment

$student = {
    ...
    points => @points,
};
[download]

is effectively this:

$student = {
    ...
    'points', 'a',
    'b', 'c',
    'd',
};
[download]

or, equivalently,

$student = {
    ...
    points => 'a',
    b      => 'c',
   'd',
};
[download]

— which explains why the compiler is warning about an odd number of elements in the hash: the last array value ('d') becomes a hash key with no associated value.

Hope that helps,

points => \@points,

Actually, that won't work here - it looks like iatros isn't using strict, or has predeclared @points outside of the loop, so that \@points and therefore $$student{points} will always point to the same array, and that array will get overwritten on each iteration of the loop. points => [@points], will work correctly, since it creates a (shallow) copy of the array. (Athanasius, I know you know all this, the explanation is for the benefit of the OP.)

iatros: You really should Use strict and warnings, and then use my to declare your variables, including inside the loop: my ( $id , $gender , $birthday ... ) = .... Then you can use both of the code examples that Athanasius showed, because then on each iteration of the loop, @points will be a "new" array.

Update: Tweaked explanation a tiny bit.

... the last array value ... becomes a hash key with no associated value.

iatros: Just another | a minor tweak to Athanasius's otherwise excellent ++explanation: The unpaired key will not have no associated value, but rather the undef value (that's where the  '.5' => undef in the OPed dump comes from). This, of course, will probably just lead to more warnings down the line!

---

Give a man a fish:  <%-{-{-{-<

Thank you for the reply. I hope I've learned my lesson with your help. I will think over the parsing thing. As Larry put it: TIMTOWTDI -HM-

Welcome to the Monastery, iatros!

I'm just about to run out the door so I don't have time for a thorough review, but one thing immediately popped out:

'points'   => @points
[download]

That's what is most likely causing the issue, because that really looks like this:

In essence, assigning an array to a hash key will attempt at adding more key, value pairs. You need to assign a reference to the array instead:

points   => \@points
[download]

Also note that in a hash, unless there are special characters involved, the "fat comma" (ie =>) will auto-quote the left-hand-side, so you don't have to in your hash creation. This is why I left the single quotes off of the key in the example above. Just makes for a bit more cleaner code.

Thanks for the reply and the tip with the auto-quote feature. Definitely more readable and less typing. Thx -HM-

You've already got some answers to your issue - just note the issue with \@points that I discussed here, including that it's a good idea if you Use strict and warnings.

Since it looks like you're parsing CSV, I'd recommend using a module for this, in particular Text::CSV:

#!/usr/bin/env perl
use warnings;
use strict;
use Text::CSV;

my $csv = Text::CSV->new({binary=>1, auto_diag=>2});
$csv->getline(\*DATA); # read and discard header
my @candidates;
while ( my $row = $csv->getline(\*DATA) ) {
    my %student;
    for my $key (qw/ id gender birthday status room seat version /) {
        # remove the first elements of the arrayref
        $student{$key} = shift @$row;
    }
    # all that's left in the arrayref is the points
    $student{points} = $row;
    push @candidates, \%student;
}
$csv->eof or $csv->error_diag;

use Data::Dump;
dd \@candidates;

__DATA__
ID,gender,birthdate,order,room,seat,version,points,,,,,,,,,,,,,,,,,,,,
+,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,
277710814533,f,01/02/1993,m,sr_3,A11,A, 1,1,1,1,0,1,1,1,.5,1,1,1,0,1,.
+5,1,1,1,0,1,.5,1,1,0,1,1,1,1,1,1,1,0,0,1,0,1,.5,1,1,1,1,.5,0,1,1,1,0,
+1,1,1,1,1,0,1,1,1,.5,1,1,1
755310765962,f,31/07/1992 00:00,v,aula,C11,C,1,.5,0,1,1,1,1,1,1,1,1,1,
+1,1,0,1,1,1,1,1,0,1,1,1,1,0,1,1,1,.5,1,0,.5,1,0,1,.5,0,.5,0,1,0,0,.5,
+1,1,0,.5,1,1,.5,.5,1,.5,.5,1,1,1,.5,.5
394610513538,m,20/10/1992 00:00,m,sr_3,E13,E,1,1,0,.5,1,1,1,1,1,1,1,.5
+,1,1,.5,.5,1,1,1,.5,.5,1,1,1,1,0,0,.5,1,1,.5,.5,.5,.5,0,1,0,.5,0,0,1,
+0,1,.5,0,1,0,0,.5,1,0,1,1,0,.5,.5,.5,.5,.5,.5
[download]

Note that DATA is a special filehandle that refers to the __DATA__ section at the end of the script, but you can use any other filehandle here, like FH in your program. Although, it'd be better to switch to "lexical" filehandles, that is open my $fh, '<', $filename or die "open $filename: $!"; (see open).

Thx for the answer. Actually I used a standard header for the script (see below). No idea why it executed despite of the nonsense.

#!/usr/bin/perl -w
use File::Basename ;
use Fcntl qw (:flock :seek) ;
use warnings ;
use strict ;

use Data::Dumper qw(Dumper);
[download]