You cannot declare a hash as a slice like that. TIMTOWTDI but I would declare the hash first, then populate it:

  my @players = qw/ barney fred dino/;
  my @bowling_scores = (195, 205, 30);
  my %score;
  @score { @players} = @bowling_scores;

  print "Tonight's players were @players\n";
  print "Their scores were: @score{@players}";
[download]

If you want to declare AND populate, the following *DESTRUCTIVE* solution works:

>perl -MData::Dumper -E "my @players = qw/ barney fred dino/; my @bowl
+ing_scores = (195, 205, 30);my %score=map{shift @players,$_} @bowling
+_scores;say  Dumper \%score"
$VAR1 = {
          'dino' => 30,
          'barney' => 195,
          'fred' => 205
        };
[download]

   my %score=map{shift @players,$_} @bowling_scores;
[download]

>perl -MData::Dumper -E "my @players = qw/ barney fred dino/; my @bowl
+ing_scores = (195, 205, 30);my %score=map{$players[$_],$bowling_score
+s[$_]} 0..$#players;say  Dumper \%score; say Dumper \@players"
[download]

  my %score=map{$players[$_],$bowling_scores[$_]} 0..$#players;
[download]

I agree that the method hippo shows here is best, but another (also non-destructive) way to initialize a hash at declaration from a pair of arrays (of equal size) is:

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"use List::MoreUtils qw(zip);
 ;;
 my @players = qw/ barney fred dino/;
 my @bowling_scores = (195, 205, 30);
 ;;
 my %score = zip @players, @bowling_scores;
 dd \%score;
"
{ barney => 195, dino => 30, fred => 205 }
[download]

G'day catfish1116,

Here's a solution which

• declares and populates the hash in one statement,
• is non-destructive, and
• uses no additional modules.

$ perl -wE '
    my @players = qw{Barney Fred Dino};
    my @bowled = (195, 205, 30);
    my %score = map +($players[$_] => $bowled[$_]), 0 .. $#players;
    say "@players";
    say "@score{@players}";
'
Barney Fred Dino
195 205 30
[download]

To hopefully avoid wrapping, I changed "bowling_scores" to "bowled". Other than than, I've used the same variable names and data that you presented.

In case you were unaware, the + in "map +(..." disambiguates map followed by an expression in parentheses (wanted) from map followed by a list of parameters in parentheses (not wanted). Try it without the + to see the difference; I get player names but no score values, and 8 warning messages.

Arrays with differing numbers of elements are not addressed here; however, your program should include some sort of validation code to handle that situation.

my %score = map { push @bowled, shift @bowled; $_ => $bowled[-1] } @pl
+ayers;
[download]