perlmoth has asked for the wisdom of the Perl Monks concerning the following question:

I am writing a script to convert source code. I want to convert lines containing things like "anStr" into {(byte)'a',(byte)'n',(byte)'S',(byte)'t',(byte)'r',}, and I came up with the following:


#!/usr/bin/perl -w

use strict;

use diagnostics;



sub jc {

  my ($c_str) = shift;

  my $j_str  = "";

  foreach (split //, $c_str) {

    $j_str = $j_str . "(byte)\'$_\',";

  }

  return $j_str;

}



while (<>) {

  s/\"(.+)\"/"{".&jc($1)."}"/e;

  print;

}

[download]

This works (except for an extra comma at the end). Is there a better way to do this?

Replies are listed 'Best First'.
Re: C to Java string conversion script
by VSarkiss (Monsignor) on Dec 01, 2001 at 21:55 UTC

    Hmm... Not sure why you'd want this, but anyway. Here's a one-liner that does it, but broken out for clarity: 

    while (<>)
{
    s|"([^"]+)"|
        '{' .
         join(',',
             map { "(byte)'$_'" }
                 split(//, $1)
             ) .
         '}'
      |gex;
    print;
}

    [download]
    Main difference is that this will match many quoted strings on a line. Like your example, it won't cope with "escaped \" quotes".

    HTH

[reply]
[d/l]
[select]
Re: C to Java string conversion script
by Fastolfe (Vicar) on Dec 01, 2001 at 22:07 UTC
    This looks like the weirdest set of requirements I've seen in a while. Maybe there is an easier way of accomplishing your goals? Not all strings in Java have to be written like (byte)'t',(byte)'h',(byte)'i',(byte)'s'.
[reply]
[d/l]
      It's for smart card code. As far as I know this is the only way to use strings on smart cards.
[reply]
Re: C to Java string conversion script
by impossiblerobot (Deacon) on Dec 01, 2001 at 21:44 UTC
    This is the quickest thing I could come up with. (I hope it works!)
    #!/usr/bin/perl -w

use strict;

print jc('anStr');

sub jc 
{
  my ($c_str) = shift;
  return '{'.join(',',(map {"(byte)'$_'"} (split(//, $c_str)))).'}';
}

    [download]

    Update: My last update didn't make much sense, so I un-updated.

    Impossible Robot
[reply]
[d/l]
Re: C to Java string conversion script
by chipmunk (Parson) on Dec 02, 2001 at 02:22 UTC
    This does the same thing, but with map and join rather than foreach and .= s/"(.+)"/'{' . join(',', map "(byte)'$_'", split m!!, $1) . '}'/e;
[reply]
[d/l]
Re: C to Java string conversion script
by converter (Priest) on Dec 02, 2001 at 08:12 UTC

    This ought to work: 

    $_ = "anStr";
{
  local $";
  $s = qq!{@{[map{"(byte)'$_',"}split//]}}!;
}

    [download]

    conv

[reply]
[d/l]
Re: C to Java string conversion script
by atcroft (Abbot) on Dec 02, 2001 at 10:22 UTC
    I am still but an egg myself, but here was what I came up with (including my testing code). Did you want a comma after the last character, as in your posting, or was that a typo? 
    #!/usr/bin/perl -- -w
use strict;
use diagnostics;

my @test = ( '"this is a test"', '"anStr"' );
foreach my $item (@test) {
    print($item, "\n", &jc($item), "\n");
}

sub jc {
    my ($line) = shift;
    my (@parts, $i);

    @parts = split('', $line);
    $parts[0] = '{';
    for ($i = 1; $i < $#parts - 1; $i++) {
        $parts[$i] =~ s/(.)/(byte)'$1',/;
    }
    $parts[$#parts - 1] =~ s/(.)/(byte)'$1'/;
    $parts[$#parts] = '}';

    return(join('', @parts));
}

    [download]
    UPDATE: In the spirit of "there's more than one way to do it", a (hopefully) cleaner version of the jc() routine than above. 
    sub jc {
    my ($line) = shift;
    my (@parts, $i);

    @parts= split('', $line);
    (undef) = shift(@parts);
    (undef) = pop(@parts);
    for ($i = 0; $i <= $#parts; $i++) {
        $parts[$i] =~ s/(.)/(byte)'$1'/;
    }

    return('{' . join(',', @parts) . '}');
}

    [download]
    I considered using a two-pass loop performing a pop() then reverse() on the array to remove the quotes on either end, but I think that would have been more work on the computer.
[reply]
[d/l]
[select]

Back to Seekers of Perl Wisdom