Consider the following code.

#/usr/bin/perl -w
use strict;
{
local $/ = "\/\/\n";

while (<DATA>) {
        #chomp;
        print "< $_ > \n";
}
}

__DATA__
first row
second row
//
another first
another second
//
one more (3.1)
one more (3.2)
//
[download]

As jeffa mentioned, the separator now will look for this sequence of characters (//\n) as a record separator. During the while loop, instead of reading one line, it will read up to this special separator.
The output will be:

< first row
second row
//
 >
< another first
another second
//
 >
< one more (3.1)
one more (3.2)
//
 >
[download]

You can easily see where each record begins and ends.
However, there is an additional effect of setting the $/ variable. It will also affect the behaviour of the chomp function.
Try it. Uncomment the line with the chomp function, and you will get this output instead:

< first row
second row
 >
< another first
another second
 >
< one more (3.1)
one more (3.2)
 >
[download]

The entire separating sequence will be chopped out, but the inner newlines will stay untouched, because they were not separators. Actually, they are part of the string, so the chomp function does not affect them.
HTH

update It's a good policy to use local with $/ to avoid side effects if your script is dealing with other input as well.

 _  _ _  _  
(_|| | |(_|><
 _|
[download]