{
  local $^I = ".bak";
  local *ARGV;
  @ARGV = ".fetchmailrc";
  while (<>) {
    s/^(here)/$username\n$1/i;
    print;
  }
}
[download]

-- Randal L. Schwartz, Perl hacker

Oooh purdy. It'd always bugged me that one "had" to use -i. It's bit unfortunate you have to go the whole ARGV/STDIN route, but that's better than forking. thanks!

--
perl -pew "s/\b;([mnst])/'$1/g"

the whole ARGV/STDIN

Excuse me? There's no use of STDIN in that program. An empty diamond is the same as <ARGV>, not <STDIN>.

And beginning Perl hackers who confuse the two will eventually get burned. My rule is to never use <> (aka <ARGV>) if you ever print some kind of prompt, and I flunk any use to the contrary in code review. Work it out for yourself to see why. The proper use for interaction where you prompt and read input is <STDIN>.

-- Randal L. Schwartz, Perl hacker

I just tried this on perl 5.005_02 and I found that it would not work with local *ARGV but local @ARGV worked.

I assume localizing the ARGV filehandle somehow broke the <ARGV> magic. It works correctly on perl 5.6.0.

It looks like it should work...

In this small snippet of code you never print your changes back to the file. You read a line in, manipulate it and throw it away. Remember that $_ holds the contents of the line. It is not the line itself.

Your immediate thought might be to add

print FETCHMAILRC $_;
[download]

What is more, when you print this line back to the file you move the file pointer on again, so your file will end up completely corrupted. A way to get around that is to use seek lots, but that's beginning to get masochistic.

If you don't like merlyn's excellent suggestion (although who wouldn't?) you can also do it this way:

open(FETCHMAILRC, '< .fetchmailrc') or die "Unable to open FMRC for re
+ading. $!";
my $filecontents;
while (<FETCHMAILRC>) {
    s/^here/$username\nhere/i;
    $filecontents .= $_;
}
close FETCHMAILRC or die "Close on FMRC died: $!";

        # clobber file and open for writing
open(FETCHMAILRC, "> .fetchmailrc') or die "Unable to open FMRC for wr
+iting. $!";
print FETCHMAILRC $filecontents;
close FETCHMAILRC or die "Close on FMRC died: $!";
[download]

Hope it helps.

jarich

There are two often used approaches for generic modifications:

• Read in the entire file into memory. Make the modifications, seek back to the beginning of the file, and print the modified content. Don't forget to perform a truncate, otherwise you may end up with trailing garbage if the modified text is smaller than the original. Obviously, this approach works better for small files than huge files.
• Use a temp file. Read in parts (for instance lines) of the original file, do the modifications, and write the modified text to the temp file. If you are all done, move the temp file to the original file.

You may want to use Tie::File, or investigate the -i option of perl itself (or its $^I equivalent).

Abigail

In which case you could do something like the following (see also perlopentut):

    open(FETCHMAILRC, '>> .fetchmailrc') or die "Unable to open FMRC."
+;

    print FETCHMAILRC $username, "\n";
[download]

If you really need to edit the file in-place then you can use the -i command line option or $^I, as demonstrated so elegantly by merlyn.

--
John.