My approach, to ensure uniqueness in values, would be to make the values the keys of hash and then transform them into an array reference.

#!/usr/bin/perl -w
use strict;
use Data::Dumper;

my %hash;

while (<DATA>) {
    next unless /[^[:space:]]/; # make sure there's something on the l
+ine

    my ($key,$value)    = split;
    $hash{$key}{$value} = 0;
}

foreach my $key (keys %hash) {
    $hash{$key} = [keys %{$hash{$key}}];
}

print Dumper \%hash;

__DATA__
5    25
6    27
5    24
5    23
6    29
6    30
4    22
5    25
6    27
4    22
4    21
[download]

Update: Everyone seems to want to push the value on an array which doesn't get the "unique values" in the original request.

Cheers,
Ovid

New address of my CGI Course.
Silence is Evil (feel free to copy and distribute widely - note copyright text)

Thanks, Ovid.

That's exactly what I was looking for!
Thanks again

my %hash;
while (<DATA>) {
    chomp($_);
    my ($first, $second) = split(/s+/, $_);
    push(@{$hash{$first}}, $second);
}

foreach my $key (keys %hash) {
    print "The $key is: ", join(', ', @{$hash{$key}}), "\n";
}
[download]

Hope this helps, -gjb-

Update: Sorry, missed the uniqueness requirement. Since a number of good solutions have already been proposed I'll just give an alternative one. (I love sets.)

use Set::Scalar;

my %hash;
while (<DATA>) {
    chomp($_);
    my ($first, $second) = split(/s+/, $_);
    if (!exists $hash{$first}) {
        $hash{$first} = new Set::Scalar();
    }
    $hash{$first}->insert($second);
}

foreach my $key (keys %hash) {
    print "The Key is: $key\n\t",
          join("\n\t", $hash{$key}->members()),
          "\n";
}
[download]

The sigil for hash is %hash. &hash is an error.

Since a hash value must be a scalar, you need to make them array references.

while (<DATA>) {
    my ($key, $val) = split;
    push @{$hash{$key}}, $val;
}
[download]

After Compline,
Zaxo

use strict;

my %hash = ();
my ($first, $second);
while (<DATA>)
{
    ($first, $second) = split;
    push (@{$hash{$first}}, $second); # from Perl Cookbook 5.7
}

while ((my $key, my $value) = each %hash) {
    print "the Key is: $key\n";
    print join("\n",@$value),"\n\n";
}

__END__
5       25
6       27
5       24
5       23
6       29      
6       30
4       22
5       25
6       27
4       22
4       21
[download]

The problem that I'm having is that all the values are being put on the array of values, and I just need the unique values I.E.

the Key is: 4
22
21

the Key is: 5
25
24
23

the Key is: 6
27
29
30
[download]

Sorry, I missed that the first time (as did some others). Here is a quick fix. Replace the final loop with this:

while ((my $key, my $value) = each %hash) {
    print "the Key is: $key\n";
    my %seen = ();
    # Perl Cookbook 4.6  Extracting Unique Elements from a List
    my @uniq = grep { ! $seen{$_}++ } @$value;
    print join("\n",@uniq),"\n\n";
}
[download]

Update: I see that Ovid also has a good one-pass solution.