Another example of bad syntax: the other day I tried redo within a do {} until block, but Perl complains that I could not use redo outside a loop block, which means Perl does not take do {} until as a loop block.

do {{
  next if /^#/;
  # do something
}} until /^\s*$/;
[download]

My suggestion is to not use those constructs altogether and instead emulate them with bare blocks and redo ...

# do {} while condition
{
  # some code
  redo if condition;
}

# do {} until condition
{
  # some code
  redo unless condition;
}
[download]

-- Hofmator

Argh. Please don't use naked blocks with redo as loops, it's a nightmare to read. When I see a naked block, I expect to be looking at a private lexical scope, not an unadorned loop. If you need next, wrap the inner part with a naked block:

do {{
    $bar;
    baz() or next;
}} while $foo;
[download]

If you need last, wrap the whole thing:

{ do {
    $bar;
    baz() and last;
} while $foo; }
[download]

Of course, if you need both, it does get awfully clumsy:

LOOP: { do {{
    $bar;
    baz() or next;
    quux() and last LOOP;
}} while $foo; }
[download]

In that case, and if you're so inclined then maybe in the other cases as well, I propose:

while(1) {
    $bar;
    baz() or next;
    quux() and last;
}
[download]

At least it documents the loop nature of the block, even if the break condition is again somewhat hidden.

Makeshifts last the longest.

well, some people think differently ... and you could always mark the bare block with a label, clearly stating what you want to do

LOOP: {
  # some code
  redo LOOP if condition;
}
 
# that's actually quite close to perl6 ;-)
loop {
  # some code
  last unless condition;
}
[download]

-- Hofmator

I think the thing with the do {} syntax is that you aren't iterating with the do block.

You are iterating the do block itself.

For example:

$i=5; print do{ --$1 };              # prints 4
$i=5; print do{ --$i } while $i;     # prints 43210
[download]

However, this is directly analogous to

$i=5; print --$1;              # prints 4
$i=5; print --$i while $i;     # prints 43210
[download]

In the latter example, its very clear that the while modifier form is iterating the print.

The former example, the while modifier is iterating the print also. It just so happens that the print has a do block as one of its terms. This is made clearer if you use the brackets on the print function like this.

$i=5;
print( do{--$i;} ) while $i;
[download]

The confusion comes because we often format the construct like this

$i=5;
do {
     print --$i;
} while ($i);
[download]

Which makes it look like an iterate-at-least-once version of

$i = 5;
while ($i) {
     print --$i;
}
[download]

But you can show the difference by doing

my ($i, $j) = (5, 0);
$j += do {
    print --$i;
} while ($i);
print $j; # prints 5.
[download]

Where the value 5 comes from the accumulation of the five 'successful' (1) return codes from the print function.

Additionally

If there is an inconsistancy with do, it's that the way it operates as an rvalue, makes it look somewhat analogous to the sort, map & grep functions, in as much as I half expected

print do( 'fred' ); to work like print do{ 'fred' } Somewhat like

 print map $_, 'fred'; is similar to print map{ $_ } 'fred';.

Actually, the error message from

 print do( 'fred' ); confuses me completly.

Actually, the error message from print do( 'fred' ); confuses me completly.

What error message? You are aware of the different variants of do? From perldoc -f do

do BLOCK
  [...]

do SUBROUTINE(LIST)
  [...]

do EXPR
  Uses the value of EXPR as a filename and executes
  the contents of the file as a Perl script.
[download]

so probably the file named 'fred' doesn't exist and do returns simply undef - at least that's what it does here (on perl 5.6.0) generating thus a warning about Use of uninitialized value in print ...

-- Hofmator

Your right of course, I didn't think about the do EXPR; form at all.

If I do print do('fred')|| warn $!;

I get No such file or directory at ...

---

Examine what is said, not who speaks.

The 7th Rule of perl club is -- pearl clubs are easily damaged. Use a diamond club instead.