Whenever you find yourself numbering individual variables instead of giving them names, you should recognise that what you ought to be using is an array.

It does away with the need for eval and it is automatically extensible.

A second thing I notice in your code is that your use of substr is wrong. The 3rd parameter to substr is the number of bytes, not the end position of the substring. As you have shown it, your variables will get larger and larger in length:

$d1 = substr($field, 0, 2);    # 2 bytes
$d2 = substr($field, 2, 2+2);  # 4 bytes
$d3 = substr($field, 4, 4+6);  # 6 bytes etc.
[download]

You also show $i+=$n in the loop increment, $i-1/$n to generate your varnames, but a fixed value of 2 in the substr?

There are several ways to do what you want without using eval or symbolic refs.

my @d;
for my $i (0 .. $length-$n) {
    $d[$i] = substr($field, $i*$n, $n)
}
[download]

Or

my @d = map{ substr $field, $_*n, $n } 0 .. ($length)/$n;
[download]

Or

my @d = unpack("A$n " x $length/$n, $field);
[download]

Or probably the simplest

my @d = $field =~ m[.{1,$n}]g;
[download]

Whenever you find yourself numbering individual variables instead of giving them names, you should recognise that what you ought to be using is an array.

Obligatory reading for more of such fundamental advice: Mark-Jason Dominus' excellent Program Repair Shop and Red Flags article series on Perl.com.

Makeshifts last the longest.

Yes, I realize this. I guess I've been programming in languages where dynamic arraying is impractical for so long that I forget that perl has such flexibility.

I didn't want to declare an array of a fixed size... and if I did, I didn't want to use an explicit for-loop (not sure why not, but the little voice in the back of my head said "hey, this is perl... you probably don't need a for loop to do that... it can probably happen in one line... it's probably a really short line, you idiot!")

Thanks for the resources, I'll read up on them! (couldn't wait, read the first... wow... so many of my programs to unbreak)

Or probably the simplest

my @d = $field =~ m[.{1,$n}]g;

OH... it is beautiful! I just plugged it into "filename -> hash" function to convert filenames such as "access_log.03020700.gz" into hashes that are something like:

{
  type => "access_log",
  year => "03",
  month => "02",
  day => "07",
  hour => "00"
  compressed => "1"
}
[download]

... needless to say, logfile munging of usage statistics is going splendidly now!

I feel like I've graduated from 1st grade of perl primary school... I'm actually Extracting Practical Reports from data!

#!/usr/bin/perl -w
use strict;

sub fixedsplit {
    my ($data,$len) = @_;
    ($data =~ /(.{1,$len})/g);
}

my $data = "abcdefghijklmnopqrstuvwxyz";
my @fields;

@fields = fixedsplit($data,4);
print "@fields\n";
@fields = fixedsplit($data,6);
print "@fields\n";
[download]

Produces:

abcd efgh ijkl mnop qrst uvwx yz
abcdef ghijkl mnopqr stuvwx yz
[download]

---
print map { my ($m)=1<<hex($_)&11?' ':'';
$m.=substr('AHJPacehklnorstu',hex($_),1) }
split //,'2fde0abe76c36c914586c';
[download]

Yes, this is clearer, and is actually pretty close to what I settled on (before the latter Monks replied). Thanks, pfaut!

Just for oddity. One-linedness is a cheat and needs 5.8 to do the string-as-file magic. {local $/ = \$n; open my $vfh, '<', \$field; @foo = <$vfh>;}

After Compline,
Zaxo

use strict;
use Data::Dumper;

my $string="abcdefghijklmnopqrstuvwxyz";
my $aryref= [];
chunk_em($string,$aryref,5);
print Dumper($aryref);

sub chunk_em {
  
  my $string=shift;
  my $aryref=shift;
  my $num=shift;
  my ($first, $second)=unpack("A${num}A*", $string);
  push @$aryref, $first;
  chunk_em($second,$aryref,5) if $second;
  return $aryref;
}
__END__
$VAR1 = [
          'abcde',
          'fghij',
          'klmno',
          'pqrst',
          'uvwxy',
          'z'
        ];
[download]

CU
Robartes-

If you're using perl 5.8 you can use the new sub-template function in unpack:

  my @d = unpack "(A$n)*", $string;
[download]

Dan Kubb, Perl Programmer

my $a = "HereIsTheStringAsString";
my $n = 5;


while($a =~/.{1,$n}/){print "$&\n"; $a = $'};

__END__

HereI
STheS
tring
AsStr
ing
[download]