I used Math::Currency:

use Math::Currency qw(Money $LC_MONETARY);
Math::Currency->format( $LC_MONETARY->{EUR} );
Math::Currency->format('MON_THOUSANDS_SEP', '\'');
print Math::Currency::Money(12345.67);
[download]

this code prints €12'345,67

HTH, Valerio

while (<DATA>) {
    chomp;
    print commify($_), "\n";
}


# From _The Perl Cookbook_, recipe 2.17

sub commify {
    my $text = reverse $_[0];
    $text =~ s/(\d\d\d)(?=\d)(?!\d*\.)/$1,/g;
    return scalar reverse $text;
}

__DATA__
195000
42000
2100
[download]

195,000
42,000
2,100
[download]

It's a lot easier in regular expressions to work from the front than from the back. With this in mind, we reverse the string and make a minor change to the algorithm that repeatedly inserts commas three digits from the end. When all insertions are done, we reverse the final string and return it. Because reverse is sensitive to its implicit return context, we force it to scalar context.

For a good time read about sexegers.


TGI says moo

-derby

From "Mastering Regular Expressions 2nd Edn" p.65

s/(?<=\d)(?=(\d\d\d)+$)/,/g
[download]

I like this because you are actually using the regex to determine the location to insert the comma, as opposed to replacing any of the original string. HTH

derby,
The only thing I would like to add is from the Perl FAQ. If you want to print money, then be sure to strip off the leading '$' (or appropriate symbol) before calling commify().

Cheers - L~R

my $amount = sprintf ('%.2f',shift());
my $s = length($amount) - 6;
while ($s > 0) {
    substr($amount,$s,0) = ",";
    $s -=3;
}
return $currency_unit.$amount;
[download]

push(@data, '189803943', '39203', '12938032');

for ( @data ) {
    print "commified: " . add_c($_) . "\n";
}

sub add_c {
   my $n = shift;

   $n = '0' x ( length($n) % 3 == 2 ? 1 : 2 ) . $n if (length($n) % 3)
+;
   $n =~ s/(...)/\1,/g;
   $n =~ s/(?:^0+,?|,$)//g;
   return($n);
}
[download]

See Zombie Nehru and take your pick.

Er.. "Commifying" a number

use Number::Format;
my $nf = new Number::Format();
my $money = $nf->format_number(195000);
[download]

$money = $nf->unformat_number($money);
[download]