Hi

You're almost there; HTML::Template expects always to get arrays of hashes to drive a TMPL_LOOP. Take another look at the section on TMPL_LOOP in the HTML::Template documentation, it should make it clearer. It'd be nice to be able to use something like Perl's $_ in a TMPL_LOOP, but this isn't possible in HTML::Template AFAIK - the value you want to print has to be value in a hash. As an example:

use strict;
use HTML::Template;
my $template_text;
{
    local $/;
    $template_text = <DATA>;
}

my $template = HTML::Template->new('scalarref' => \$template_text);
my $sections = [
    { 'section_name' => 'Foo',
      'sub_sections' => [
          { 'sub_section_name' => 'Foo part 1' },
          { 'sub_section_name' => 'Foo part 2' },
          { 'sub_section_name' => 'Foo part 3' }
      ]
    },
    { 'section_name' => 'Bar',
      'sub_sections' => [
          { 'sub_section_name' => 'Bar part 1' },
          { 'sub_section_name' => 'Bar part 2' },
          { 'sub_section_name' => 'Bar part 3' }
      ]
    }
];


$template->param('section_names' => $sections);
print $template->output;


__DATA__
<TMPL_LOOP NAME=SECTION_NAMES>
    <p><b><input type="radio" name="section" value="<TMPL_VAR SECTION_
+NAME>" /><TMPL_VAR SECTION_NAME>:</b></p>
    <TMPL_LOOP NAME=SUB_SECTIONS>
        <blockquote><input type="radio" name="subSection" value="<TMPL
+_VAR NAME=SUB_SECTION_NAME>" /><TMPL_VAR NAME=SUB_SECTION_NAME></bloc
+kquote>
    </TMPL_LOOP>
    
</TMPL_LOOP>
[download]

HTH
ViceRaid

Got it! Thanks! :)

You can't use $_ in a <TMPL_LOOP>, but you can use map to turn a flat list into a list of hashes:

'sub_sections' => [
    map {{ 'sub_section_name' => $_ }} 'Foo part 1', 'Foo part 2', 'Fo
+o part 3'
      ],
[download]

--bwana147