"\1" means the first opened parenthesis. You need to use "\2".

$ perl -e '$_="aaabbccccddeee"; print $1,$/ while /((.)\2*)/g'
#                                                  ^^
#                                                  ||
#                                                  |+--- \2
#                                                  |
#                                                  \1
aaa
bb
cccc
dd
eee
[download]

Or, if you want an array as a result,

 push @array, $1 while  /((.)\2*)/g;
[download]

Update
Notice that you can't just assign the outcome of the regex to an array, because you'd get redundant results (both $1 and $2 for each match).

# THIS IS WRONG
@array = $_ =~ /((.)\2*)/g;
print join ", " , map {"<$_>"} @array;
__END__
<aaa>, <a>, <bb>, <b>, <cccc>, <c>, <dd>, <d>, <eee>, <e>
[download]

 _  _ _  _  
(_|| | |(_|><
 _|   

 push @array, $1 while  /((.)\2*)/g;
[download]

nicely demonstrates the difference between capturing for backreference and capturing for return value. I wonder if Perl 7 will make that distinction?

-QM
--
Quantum Mechanics: The dreams stuff is made of

Thanks for the double quick reply

I can see it was a mistake trying to use split, which is why I was pratting about with the (?:) grouping in the first place.

I'm getting older and wiser all the time (well, older anyway)...

A few ways to do it, for variety:

my $str= "aaabbccccdd eee";
my @list;
my $pos= 0;
while(  $str =~ /(?<=(.))(?!\1)/g  ) {
    push @list, substr( $str, $pos, pos($str)-$pos );
    $pos= pos($str);
}
[download]

my @list= split /(?<=(.))(?!\1)/, "aaabbccccdd eee";
@list= @list[ map 2*$_, 0..@list/2-1 ];
[download]

Scan string.....

use Data::Dumper;
my $str = "aaabbccccdd eee";

my $last = '';
my @res;
my $i = -1;
for my $chr ( split //, $str ) {
    $i++ unless $chr eq $last;
    $res[$i] .= $chr;
    $last = $chr;
}

print Dumper \@res;

__DATA__
$VAR1 = [
          'aaa',
          'bb',
          'cccc',
          'dd',
          ' ',
          'eee'
        ];
[download]

OK so it looks like C without the pointers. So shoot me!

Well, I did have something similar in reserve, but wanted to make it a bit more regexpy for a laugh!

Thanks for the reply

Why? Less written code == faster => no; some regexp solution is 'cooler' == you say; posting to PM for a 5 line answer in almost any lang is efficient......

cheers

tachyon

s&&rsenoyhcatreve&&&s&n.+t&"$'$`$\"$\&"&ee&&y&srve&&d&&print

Then why watse our time? Why not go: "this does what I want but..." for some inexplicable reason I need TIMTOWDI. Despite the fact that what I have what I need, with no speed justification/benchmark at all, I would like you all to solve a problem I have already solved, for no particular reason, for free, for someone you dont know......

I am surprised there is less enthusiasm.

• Solving problems is one thing
• Solving solved problems is antoher thing
• Solving problems for someone who then goes on to go..... might possible erode the milk of HK. JM2c.

cheers

tachyon

s&&rsenoyhcatreve&&&s&n.+t&"$'$`$\"$\&"&ee&&y&srve&&d&&print

echo 'aaabbccccdd eee' | perl -aF'(.)(?!\1)' -lne 'while(@F){push@M,sh
+ift(@F).shift(@F)}print for @M'
[download]

Producing:

aaa
bb
cccc
dd

eee
[download]

Update:

Shorter :

echo 'aaabbccccdd eee'|perl -aF'(.)(?!\1)' -lne 'for(@F){$M[$c].=$_;$c+=$d++%2}print for @M'

Not using split, and shorter still:

echo 'aaabbccccdd eee'|perl -lne 'while($_){s/((.)\2*)//;push@F,$1}print for @F'

Thanks to everyone for the replies - they're most appreciated.

Well here's another way, when you want only a part of a list, grep comes to my mind:

grep { ++$i % 2 } /((.)\2*)/g
[download]

$anarion=\$anarion;

s==q^QBY_^=,$_^=$[x7,print

Ok, I'm cheating but what the heck ...

use Data::Dumper qw/Dumper/;
$_ = "aaaabbbcccccdd eeef";
print Dumper([
    keys %{{ split /(?<=(.))(?!\1)/x }}
]);
__END__
$VAR1 = [
          'ccccc',
          'eee',
          'aaaa',
          ' ',
          'bbb',
          'dd',
          'f'
        ];
[download]

Any comments ?