Are there any strings in your logfile array containing CSS which shouldn't be altered? If not, you could just go with 

for (@filenames) {
    s/CSS//;
}

# or written with a statement modifier:
# s/CSS// for @filenames;

[download]

You could run the above code over your array and check for false positives, and extend the regular expression if so.

Since your strings are tokens concatenated with a dot, of which the last is always ErrorLog, you could anchor your regular expression at the end with $ and remove CSS from the token preceeding the last two: 

for (@filenames) {
    s{           # substitute 
      CSS        # the string CSS 
      (          # and a capture consisting in
        \.       # a literal dot,
        [^\.]+   # any number of non-dots,
        \.       # another literal dot,
        ErrorLog # and the constant ErrorLog
      )          # (end of capture)
      $          # anchored at the end of the string
    }
    {$1}x;       # against the capture above
}

[download]

Or written more concisely with a terse explanation:

for (@filenames) {
    s/CSS(\.[^\.]+\.ErrorLog)$/$1/; # remove CSS from end of antepenul
+timate token
}

[download]

Perhaps more effective and faster, if you have only a few strings with CSS: look for CSS, if found, split, remove and join:

for (@filenames) {
    if (/CSS/) {
        my @t = split /\./;
        $t[-3] =~ s/CSS$//;
        $_ = join '.', @t;
    }
}

[download]
perl -le'print map{pack c,($-++?1:13)+ord}split//,ESEL'

In reply to Re: Perl file name parsing - Regular expression by shmem
in thread Perl file name parsing - Regular expression by rinkish85

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.