What's going on behind the scenes is actually pretty interesting. So when you say PPI::Document->new(\$sub_h{$name}{content})->find_first('PPI::Statement::Sub'), you're creating a new document, however, you're not keeping a reference to that document, so it is immediately DESTROYed - which clobbers every element of that document - including the sub returned from find_first!

So to fix that, split that statement into two, saving the document in a variable so that it is not immediately destroyed. But the code still doesn't work, because that document is still getting destroyed at the end of the loop body, removing the elements before you get to save. So to fix that, you need to disassociate the sub element from its document via remove.

There's one more minor issue, which is that you need to remove the stub, since you're replacing it with the stored one. So putting all that together gets you this, which works (file after should be identical to before):

#!/usr/bin/env perl
use warnings;
use strict;
use 5.010;
use PPI;

my $raw = <<'__RAW__';
package FeeFi;
sub Fee {
    print "Fee\n";
}
sub Fi {
    print "Fi\n";
}
1;
__RAW__

my %sub_h;
{
    my $document = PPI::Document->new(\$raw)
        or die "oops!";
    $document->save('before');
    for my $sub (@{$document->find('PPI::Statement::Sub') || []}) {
        next if $sub->forward;
        $sub_h{$sub->name}{content} = $sub->content;
        my @elements = $sub->block->children;
        for (my $i=0; $i < @elements; $i++) {
            $elements[$i]->remove;
        }
    }
    $sub_h{''}{content} = $document->content;
}
{
    my $document = PPI::Document->new(\$sub_h{''}{content})
        or die "oops creating ''!";
    for my $stub (@{$document->find('PPI::Statement::Sub') || []}) {
        next if $stub->forward;
        # 1. store the document in its own variable
        my $doc = PPI::Document->new(\$sub_h{$stub->name}{content});
        my $sub = $doc->find_first('PPI::Statement::Sub');
        # 2. remove the sub element from its document
        $stub->insert_after($sub->remove)
            or warn "Can't insert_after!";
        # 3. remove the stub
        $stub->remove;
    }
    $document->save('after');
}

[download]

In reply to Re: PPI replacing/updating a stub by haukex
in thread PPI replacing/updating a stub by clueless newbie

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.