opendir(DIR,$str);

[download]

See opendir. That's for reading a directory.

If you want to write files into a directory, name it. open doesn't guess, and doesn't magically prepend a path component to the file name; opendir doesn't set a directory context for open. 

for my $key (keys %hash){
  my $outputfile = "output_$key";
  $outputfile =~ s{/}{-}g;
  $outputfile = join '/', $str,$outputfile; # <---- this is missing
  print "Writing to $outputfile\n";
  open OUT,'>',$outputfile 
       or die "Could not open $outputfile : $!";
  print OUT $hash{$key};
  close OUT;
}

[download]

Better alternative to join, because it is portable (Windows etc):

use File::Spec;
...
for my $key (keys %hash){
  ...
  $outputfile = File::Spec->catfile($str,$outputfile);
  ...
}

[download]

update:

Re-reading the question and code, it looks like you mistook opendir for chdir which sets the current working directory. Cwd comes in handy:

#!/usr/bin/perl
use strict;
use warnings;
use Cwd;

my %hash=();

# input
# my $inputfile = 'nv.txt';
# open IN, '<',$inputfile 
#     or die "Could not open $inputfile : $!"; 

# we use the text after __DATA__ for input
while (<DATA>) {
  my ($key, $val) = split (/:/,$_,2);
  $hash{$key} .= $val;
}

# output
my $dir = "dict";
-d $dir or mkdir $dir;
my $cwd = getcwd(); # from Cwd imported above
chdir $dir; # go into directory 'dict'
for my $key (keys %hash){
  my $outputfile = "output_$key";
  $outputfile =~ s{/}{-}g;
  print "Writing to $outputfile\n";
  open OUT,'>',$outputfile 
       or die "Could not open $outputfile : $!";
  print OUT $hash{$key};
  close OUT;
}
chdir $cwd; # change directory back




__DATA__
test/right/case1:12: //comment
test/right/case1:344: //comment
test/wrong/case3:123:  //comment
Output expected:
test/right/case1: 12: //comment
                :344: // comment
test/wrong/case3:123: //comment

[download]
perl -le'print map{pack c,($-++?1:13)+ord}split//,ESEL'

In reply to Re^3: append files to a directory by shmem
in thread append files to a directory by harishnv

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.