It's not exactly simple, but here's how to do it the old-fashioned way with pipe, sysread, and syswrite. Note how the pipe protocol uses the number of bytes transferred in every message to detect its length: 
use strict;

my @array = ();

pipe my $read, my $write or
    die "Cannot open pipe";

for(1..3) {
    defined(my $pid = fork) or die "Can't fork\n";

    if($pid) {
        next;  # Parent: continue loop
    }

        # Child
    pipe_send($write, "I'm process $$!");
    exit 0;
}

# Parent
for(1..3) {
    my $element = pipe_recv($read);
    push @array, $element;
}

print "array = @array\n";

##################################################
sub pipe_send {
##################################################
    my($fh, $message) = @_;

    my $bytes = sprintf "0x%08x", length($message);
    syswrite($fh, $bytes . $message);
}

##################################################
sub pipe_recv {
##################################################
    my($fh) = @_;

    die "Protocol corrupted" if
        sysread($fh, my $bytes, 10) != 10;
    $bytes = hex($bytes);

    my $data = "";
    while($bytes != 0) {
        my $read = sysread($fh, my $chunk, $bytes);
        last unless defined $read;
        $bytes -= $read; $data .= $chunk;
    }
    return $data;
}

[download]

In reply to Re: simple IPC by saintmike
in thread simple IPC by keithw99

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.