If the data file is not too large you could slurp it into a single string and use a regex to pull out groups of lines with the parts to concatenate in separate memory groups.

use strict;
use warnings;

open my $dataFH, q{<}, \ <<END_OF_FILE or die qq{open: $!\n};
library_AND
PIN.A
DELAY_TABLE 1 20 2 40 3 60 4 65 5 75;
DELAY_TABLE 1 10 2 15 3 45 4 70 5 80;
POWER_TABLE 20 30 40 50 80 97 110 20;
POWER_TABLE 3 4 5 6 10 80 90 10 20;
library_BUF
PIN.B
LEAKAGE 1 2 3 4;
TRANSIT 1.1 2 3.4;
END_OF_FILE

my $dataString = do
   {
       local $/;
       <$dataFH>;
   };

close $dataFH or die qq{close: $!\n};

my $rxGroup = qr
   {(?xs)
       (library_[^\n]+)\n
       ([^\n]+)\n
       (.*?\n)
       (?=(?:library_|\z))
   };

while ( $dataString =~ m{$rxGroup}g )
{
    print qq{$1:$2:$_\n} for split m{\n}, $3;
}

[download]

Here's the output.

library_AND:PIN.A:DELAY_TABLE 1 20 2 40 3 60 4 65 5 75;
library_AND:PIN.A:DELAY_TABLE 1 10 2 15 3 45 4 70 5 80;
library_AND:PIN.A:POWER_TABLE 20 30 40 50 80 97 110 20;
library_AND:PIN.A:POWER_TABLE 3 4 5 6 10 80 90 10 20;
library_BUF:PIN.B:LEAKAGE 1 2 3 4;
library_BUF:PIN.B:TRANSIT 1.1 2 3.4;

[download]

I hope this is useful.

Cheers,

JohnGG

Update: Removed superfluous my $group = from while clause, left over from earlier version. Original line was

while ( my $group = $dataString =~ m{$rxGroup}g )

[download]

In reply to Re: Need help with line concatenation by johngg
in thread Need help with line concatenation by noobee

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.