Luftkissenboot:

If you can make all your consolidation functions able to work incrementally, you could process your data one row at a time. Even if you can't make the function work incrementally, you might be able to transform it such that you can use partial results and combine them at the end (last line of example before __DATA__ statement). Something like this:

#!/usr/bin/perl -w
#
# Sploink.pl
#
use strict;
use warnings;

sub make_summer {
        my $sum = 0;
        return sub { $sum += $_[0]; }
}

sub make_minner {
        my $min = 9.99e99;
        return sub {
                $min = $_[0] if $_[0] < $min;
                return $min;
        }
}

sub make_avger {
        my ($cnt, $sum) = (0, 0);
        return sub {
                $sum += $_[0];
                ++$cnt;
                return $sum/$cnt;
        }
}

sub make_counter {
        my $cnt = 0;
        return sub { ++$cnt }
}

my @funcs = (
        make_summer(),
        make_minner(),
        make_avger(),
        make_avger(),
        make_counter(),
);

my @results;
while (<DATA>) {
        chomp;
        my @flds = split /\s+/;
        $results[$_] = $funcs[$_]($flds[$_]) for (0 .. $#funcs);
}

print "results: ", join(", ", @results), "\n";
print "avg of column 1 is: ", $results[0] / $results[4], "\n";
__DATA__
10 20 30 40
12 14 16 18
9  10 11 12
13 14 15 16

[download]

Which gives the following:

roboticus@swill: /Work/Perl/PerlMonks
$ ./sploink_739466.pl
results: 44, 10, 18, 21.5, 4
avg of column 1 is: 11

[download]

...roboticus

UPDATE: Added program output

In reply to Re: An efficient, scalable matrix transformation algorithm by roboticus
in thread An efficient, scalable matrix transformation algorithm by Luftkissenboot

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.