Your data structures look more like arrays. The standard idiom for a random selection from an array is $array[rand @array]. If you want a shuffle, there is one in List::Util.

Syntax error. I think you wanted @verbs, and @pronouns, not hash.

You can do something like:

use warnings;
use strict;

my @verbs =
("jumped","eat","killed");

my @pronoun =
("I","You","He","She");
while (1) {
    print $pronoun[rand @pronoun] . " " . $verbs[rand @verbs], "\n";
    sleep(1);
}
[download]

use strict;
use warnings;

my @pronouns = qw/He She I Me/;
my @verbs = qw /jumped ate laughed cheated/;

print $pronouns[rand @pronouns] .
      ' ' . 
      $verbs[rand @verbs] . $/;
[download]

-enlil

The fact that it looks more like you should be using an array notwithstanding, I'll go ahead and answer the question asked in the subject line anyway:

Here is one way to select a single random element from a hash:

my $randelement = ( keys %hash )[ rand( scalar keys %hash ) ];
[download]

This works by creating a list of the keys, and then by generating a random number between zero and n, where n is the number of keys. Using keys in scalar context is an efficient way of determing the number of keys in the hash. That random number is then used as a list index (like an array index) to grab the element corresponding with that random index number. The fact that rand generates floating point numbers doesn't matter; array and list indices are implicitly truncated to integers. That also means that 10.999 will be the element number 10, which is the 11th element. And 0.999 will be element number 0, the 1st element.

If you're going to be grabbing several elements, and don't want to repeat, use a Fisher Yates shuffle, from List::Utils and then iterate over the list.

What's wrong with:

%verbs =
{"jumped","eat","killed"};

%pronouns =
{"I","You","He","She"};

my @pronouns = shuffle keys %pronouns;

foreach my $verb (shuffle keys %verbs)
{
  print shift(@pronouns), ' ', $verb, "\n";
  @pronouns = shuffle keys %pronouns if (scalar(@pronouns) == 0);
}
[download]

Well, for one thing { } is the anonymous hashref constructor and you'd get an odd-number-of-elements-in-hash-assignement warning. And for another you left off use List::Util qw( shuffle ).

The keys of %verbs are "jumped" and "killed". The values associated with those keys are "eat" and undef.

The keys of %pronouns are "I", and "He". The values associated with those keys are "You" and "She".

So you're shuffling two pronouns, not four, and two verbs, not four. So the only possible pronouns, given your code, will be "I" and "He". "She" and "You" will never be selected. Bummer for you and her. ;)

And with your code (assuming you fixed the missing List::Utils, and uneven key/value pairs), the only actions that He and I could perform would be jumped and killed. ...we would never eat.




Dave