my $foo = Obj->new;
for (qw( create init add )) {
  $foo->$_();  # note -- $foo->$_ will not work, ()'s needed
}
[download]

my $meth = 'meth';
$A::B::{$meth}->(25);
# %A::B:: is a symbol table
# $A::B::{$meth} holds the typeglob *A::B::meth
# *A::B::meth->(...) is like A::B::meth(...)
[download]

#!/usr/bin/perl

use strict;

@:: = qw( this program uses empty variable names );
for $:: (@::) { print $::; }  # ::; looks confusing ;)
open ::, ".cshrc";
print scalar <::>;  # is there no end to this madness?
close ::;
[download]

you can, try this

package A::B;

sub meth {
   warn "meth $_[0]", "\n";
}

my $meth='meth';

A::B->$meth(25); # succeeds...not really what you are likely expecting
&$meth(26); # succeeds in calling

my $foo="A::B::meth";
&$foo(27); # also succeeds
[download]

outputs

meth A::B
meth 26
meth 27
[download]

I'd rather leave it up to more elequent monks seeking high xp to explain this one. (better to remain silent and be thought an idiot that to speak and remove all doubt) :-)

"Methods" normally act on an object, which passes the object reference as the first argument. Methods can also act on packages (using a similar notation), passing the name of the package as the first argument. The key difference is in how you want to interpret the subroutine. Do you need it to be a simple subroutine (without care as to the object/package context), or do you need it to be a method, with knowledge of the object or package? If you need it to be a simple subroutine, write it as such and either export it, or call it as A::B::sub($arg1, $arg2). If you need it to be a method, that's when you use the arrow notation.

package A::B;

sub new {
   my $caller = shift;
   my $self = {};

   bless $self, ref($caller) || $caller;
}

sub method {
   my $self = shift;
   my @args = @_;

   print "self=$self, args=@args\n";
}

sub function {
   my @args = @_;

   print "args=@args\n";
}

package main;

$self = new A::B;     # A::B::new as a package method,
                      # first arg = "A::B";
$self = A::B->new;    # A::B::new as a package method,
                      # first arg = "A::B";
$self = $self->new;   # A::B::new as an *object* method,
                      # first arg = $self, ref($self) = "A::B"

&A::B::function("some", "args");      # don't care about $self or A::B

$self->method("some", "args");        # Need to know $self
&A::B::method($self, "some", "args"); # Same results, weird methodolog
+y

A::B->method("some", "args");         # Need to know name of package
[download]

Typically package methods are only useful when creating a new object that might rely on inheritance. If you create a descendent object, and simply want to inherit the parent's "new" constructor, simply using bless without a second argument will cause the new object to be blessed into the parent class. Providing that first argument to the 'new' method and passing it as the second argument to bless causes it to be blessed into the class that your code originally used. Similarly, using ref as above allows you to create new objects via a pre-existing object ($self->new).

Other than that, the only reason you might want to use a package method is for readability.

It works because it's a soft reference. You shouldn't use soft references except in ONE specific application (importing symbols from one package to another.

$_="goto+F.print+chop;\n=yhpaj";F1:eval

my $coderef = A::B->can($meth);
...
$coderef->("A::B", 25);
[download]

-- Randal L. Schwartz, Perl hacker

Hello,

I have a similar problem. I want to call a class method of a "dynamic" class "dynamically", i.e. I want to make a call like

my $result = MODULES::$submodule::$method ($data);
[download]

I tried different things like

my $request = "MODULES::$submodule::$method";
my $result  = &$request ($data);
[download]

or

my $result = eval "$request ($data)";
[download]

but I didn't succeed. The even worst thing is that the program keeps on running without any error, only the method trying to call another method seems to "die" without any hint.
Actually this problem is common to my current project. Does anybody have a clue about that?

Thanks.

Marco

If it's a static method then you could do this

my $result = "MODULES::$submodule"->can($method)->($data);
[download]

This works because can is returning a reference to the subroutine in MODULES::$submodule and then that it is being called with $data being passed in.

Or, simpler still, if it's a class method then you don't need any trickery

my $result = "MODULES::$submodule"->$method($data);
[download]

That just uses the string "MODULES::$submodule" as the class and then calls the method as designated by $method.
HTH

_________
broquaint

Excellent, thank you.

One of my mistakes was to put the method name between the quotation marks like

my $result = "MODULES::$submodule->$method($data)"
[download]