#!/usr/bin/env xsh

$file = open "myfile.xml";
insert comment "BOX1" replace //span[id="box1"];
save;
[download]

Well, if you add /s to what you have, everything between and including $first and $last will be replaced. You say this didn't work for you?

Here's a useful mnemonic to remember the difference between /s and /m:

/s affects the meaning of a single regexp character (namely "."), while /m affects the meaning of multiple regexp characters (actually, just two: "^" and "$").

BTW, the parentheses in your regexp are superfluous, since you are not doing anything with the captured string, and in this case they are not needed for grouping either.

But despite my giving you these pointers on your regexp, I agree with merlyn that regexps are not the tool for this kind of problem.

I just realilzed I had a typo, which is why it didn't work, Duh!

Just in case you're curious, from s/$first(.*?)$last/$reserve/s;
I took out "(.*?)$last" and tried it, worked in a funny way.
so I tried it without the "$first(.*?)" instead, and it failed completely.

So looking at my actual code, I found a space between the used example: "/ span>" for $last.

So the little things will get ya if you are not getting enough sleep :)

Thank you very much for building my confidence with the way I was sure to be right with previous help from all you perl monks.

First, you'll escape all special characters in $first and $last, or use \Q...\E. (I can't believe noone else mentioned this.)

Secondly, if you match $first and $last, you need to reinsert them:

$string =~ s/(\Q$first\E).*?(\Q$last\E)/$1$reserve$2/;
[download]

or use a zero-width assertion:

$string =~ s/(?<=\Q$first\E).*?(?=\Q$last\E)/$reserve/;
[download]

Since you're constant strings, you could also use index instead of regexp:

$first_start = index($_, $first);
if ($first_start >= 0) {
   $first_end = $first_start + length($first);
   $last_start = index($_, $last, $first_end);
   if ($last_start >= 0) {
      substr($_, $first_end, $last_start, $replace);
   }
}
[download]

If you want to replace a substring bounded by other substrings:

my $alpha = join '', ('a'..'z');  # $alpha = 'abcdefghijklmnopqrstuvwx
+yz'
$alpha =~ s/(?<=def).*(?=uvw)//;  # remove everything preceeded by the
+ substring 'def'
                                  #   and succeeded by the substring '
+uvw'
print $alpha;                     # $alpha = 'abcdefuvwxyz'
[download]

Consult perlre and perlretut for more on the formation of regular expressions; however, given your example using HTML, I presume you may really be looking for HTML::Template and similar modules.

$string =~ s/$first(.*?)$last/$reserve/s;
[download]

$string =~ s/$first.*?$last/$reserve/s;
[download]

An s flag tells the regex to ignore line boundaries, which it won't do normally.

I wouldn't put it that way. /s makes newlines a valid match for ".". Moreover, perl normally does ignore internal line boundaries unless one tells it not to with /m. E.g.

my $s = "a\nb\nc\n";
my @g   = map "[$_]", $s =~ /(.)$/g;
my @gs  = map "[$_]", $s =~ /(.)$/gs;
my @gm  = map "[$_]", $s =~ /(.)$/gm;
my @gsm = map "[$_]", $s =~ /(.)$/gsm;
print "g:   @g\n";
print "gs:  @gs\n";
print "gm:  @gm\n";
print "gsm: @gsm\n";
__END__
g:   [c]
gs:  [c] [
]
gm:  [a] [b] [c]
gsm: [a] [b] [c] [
]
[download]

Note in particular the case in which both /s and /m are used.

the lowliest monk