You got nothing because (\.)+ matches one or more occurences of a single literal period. You mean /interface (.+)$/ instead.

Ah,...I blame it on the migrain that I have been getting on almost daily basis.

Perl Monks seems to be my only remedy at the moment.


Blackadder

Try this out.

use strict;
use warnings;

# See perlvar for why $/ = "" causes $record to contain your entire re
+cord at once. The point is to read your data record-at-a-time instead
+ of line-at-a-time.
local $/ = "";
while ( my $record = <DATA> ) {

    # See perlre for why (.+) fetches everything on the same line as t
+he text being matched but doesn't continue onto the next line. Rememb
+er, $record is a multi-line string.
    my ( $pc_name ) = $record =~ /interface (.+)/;
    my ( $switch_name ) = $record =~ /switchport description (.+)/;

    print "$pc_name: $switch_name\n";
}
[download]

Yes, Local $/ has sorted most of my issues.

Thanks
Blackadder

. means "any one character".
\. means "one period".
You keep using the wrong one.

You used (XXX)+ where you mean (XXX+).

Then there's using $2 when the regexp only has one capture.

You didn't create any records for interfaces with no descriptions (but your desired output indicates you want this).

$Recs is a more accurate name for $Rec.

The XXX, XXX if XXX syntax is unusual and therefore harder to read.

Recs has no reason for being a hash reference. A hash is sufficient.

Your indenting is inconsistent. Pick a style and stick with it.

use warnings was missing. It would have identified your problems here.

use strict;
use warnings;

my %Recs;
my $pc_name;

while (<DATA>) 
{
    if (/interface (\S+)$/) {
        $pc_name = $1;
        $Recs{$pc_name} = {};   # Create record.
        next;
    }

    if (/switchport description (.*)$/) {
        $Recs{$pc_name}{description} = $1;
        next;
    }
}

for $pc_name (keys %Recs)
{
    my $description = $Recs{$pc_name}{description};
    if (defined $description) {
        $description = "switchport description $description";
    } else {
        $description = "";
    }
    print("interface $pc_name = switchport description $description\n"
+);
}
[download]

use strict;
use warnings;

my %descriptions;
my $pc_name;

while (<DATA>) 
{
    if (/interface (\S+)$/) {
        $pc_name = $1;
        $descriptions{$pc_name} = undef;
        next;
    }

    if (/switchport description (.*)$/) {
        $descriptions{$pc_name} = $1;
        next;
    }
}

for $pc_name (keys %descriptions)
{
    my $description = $descriptions{$pc_name};
    if (defined $description) {
        $description = "switchport description $description";
    } else {
        $description = "";
    }
    print("interface $pc_name = switchport description $description\n"
+);
}
[download]

Update: Added missing paren.

Update: Added creation of records with no description.

Hm, well...

If you just want to print these values out:

while (<DATA>) {
    chomp;
    print "\n$1 =" and next if /^(interface\s.+)/;
    print "$1" and next if /^\s+(switchport description\s.+)/;
}
[download]

If getting them into a hash is the point:

my (%data, $last);
while (<DATA>) {
    #~ print STDERR $_;
    chomp;
    if (/^(interface\s.+)/) {
        $last = $1; 
        $data{$last} = '';
        next;
    }
    $data{$last}=$1 and next if /^\s+(switchport description\s.+)/;
}

##now print
for ( sort keys %data ) { print "$_ = $data{$_}\n" }
[download]

The main problems you're having are illuminated in the posts above, so I won't belabor them. Just read perlre and perlretut again, and maybe pick up a copy of Mastering Regular Expressions (ISBN 0596002890).

my ($Rec,$pc_name);

while (<DATA>)
{
  $pc_name = $1, next if (/^(interface .+)$/);
  $Rec->{$pc_name} ||= undef;  ## let it exist
  $Rec->{$pc_name} = $1 if (/^\s+(switchport description .+)$/);
}

for (sort keys %{$Rec}) {
  my $val = $Rec->{$_} ? $Rec->{$_} : "";
  print "$_ = $val\n";
}

__OUTPUT__

interface fc1/1 = switchport description Trunk
interface fc1/10 = 
interface fc1/11 = switchport description DMX02_FA7CA
interface fc1/12 = 
interface fc1/13 = 
interface fc1/14 = 
interface fc1/15 = 
interface fc1/2 = 
interface fc1/3 = 
interface fc1/4 = 
interface fc1/5 = 
interface fc1/6 = 
interface fc1/7 = switchport description DMX02_FA4CA
interface fc1/8 = 
interface fc1/9 = 
interface mgmt0 =
[download]

This is ok if you don't mind the different order of the output lines.