my (%inf,@info,@keys,$phile,$key,$value);
[download]

Generally no need to have such long declarations. Declare as close as possible to the actual use of the variable.

use Cwd;
my $dir=Cwd->getcwd();
opendir(DIR,"$dir")or die "@!";
[download]

"@!"?!?

while ( $phile=readdir(DIR)){
        if($phile=~/^\.$/){next;}
        elsif($phile=~/^\.\.$/){next;}
[download]

How 'bout

next if $phile =~ /.../;
[download]

instead? Also, regexen are great, but how 'bout

next if $phile eq '.' or $phile eq '..';
[download]

which is not exactly what you do, but is what I think you want to do.

        elsif($phile=~/^(.*)$/)
[download]

"else if it matches anything else"...

        {print "$phile\n";info($phile)}
        info ($phile);
        }
[download]

Huh?!? Twice?

sub info{
         @info=stat($phile);
        @keys=qw(Dev Inode Mode NLink UID GID RDev Size ATime CTime Bl
+ksize Blocks);
[download]

Huh?!? Why passing it as a parameter if you use it as a "global"? Just adopt a proper form of the former option! (See perldoc perlsub)

All in all if I understand correctly what you're after, it may be as simple as:

#!/usr/bin/perl

use strict;
use warnings;
use Data::Dumper;

use Cwd;
my $dir=Cwd->getcwd;
opendir my $dh, $dir or die
  "Can't open `$dir': $!\n";

while (my $file=readdir $dh) {
    next if $file eq '.' or $file eq '..';
    print $file, "\n";
    my %tmp;
    @tmp{qw/Dev Inode Mode NLink UID GID RDev Size ATime CTime Blksize
+ Blocks/}=
      stat $file;
    print Dumper \%tmp;
}

__END__
[download]

(using Data::Dumper for lazyness!)