my @keepers;
foreach my $i (0..$#array1)
{
    push @keepers, $i if $array1[$i] =~ /keep these/;
}
@array1 = @array1[@keepers];
@array2 = @array2[@keepers];
[download]

Just for giggles, here's that using grep:

my @keepers = grep { $array1[$_] =~ /keep these/ }
              0 .. $#array1;
@array1 = @array1[@keepers];
@array2 = @array2[@keepers];
[download]

And to avoid the temp variable — not really a valid goal, but kind of fun — and not repeat the grep:

my @a1 = qw'only keep ones that have es';
my @a2 = qw'art  bart cart dart eart good';

@a1 = @a1[sort {$a <=> $b} grep {$a1[$_] =~ /e/ or do { splice @a2, $_
+, 1; 0 } } reverse 0..$#a1];
print "@a1\n@a2\n";
[download]

It gets a little complicated, mostly because of the gyrations necessary to splice out the right element after others have been removed.

---

Caution: Contents may have been coded under pressure.

So to be inefficient and avoid the temp variable (untested):

@array1 = @array1[+grep 
                   { $array1[$_] =~ /keep these/ }
                   0 .. $#array1
                 ];
@array2 = @array2[+grep 
                   { $array1[$_] =~ /keep these/ }
                   0 .. $#array1
                 ];
[download]

-QM
--
Quantum Mechanics: The dreams stuff is made of

my %hash;
@hash{ @array1 } = @array2;
my @array1 = grep( ! /foo/, keys %hash );
my @array2 = map { $hash{$_} } @array1;
[download]

my @array = grep
    $_->[0] !~ /someRE/,
      map { [ $array1[$_], $array2[$_] ] }
        0 .. $#array1;
@array1 = map { $_->[0] } @array;
@array2 = map { $_->[1] } @array;
[download]

@ary1= (1,2,3,4,3);
@ary2= (a,b,c,d,u);

print "Before\n";
print "@ary1","\n";
print "@ary2","\n";

$cnt=0;
foreach (@ary1)
{
push(@new_ary,$cnt), if($_ =~ /3/);
$cnt++
}

splice(@ary1,$_,1,"undef"), for(@new_ary);
splice(@ary2,$_,1,"undef"), for(@new_ary);

@ary1 = grep{!/undef/} @ary1;
@ary2 = grep{!/undef/} @ary2;

print "\nAfter\n";
print "@ary1","\n";
print "@ary2","\n";
[download]