Re: combine two AoHs

@c = map { +{%{$a[$_]}, %{$b[$_]}} } 0 .. @a - 1;
[download]

Update: it appears that I've interpreted your question differently from diotalevi. Here's an example on when they're different.

#!/usr/bin/perl

use strict;
use Data::Dump::Streamer;

my @a = ({ domain => 'adomain.com',
          data => 'adata',
        },
        { domain => 'bdomain.com',
          data => 'bdata',
        });

my @b = ({ domain => 'bdomain.com',
          otherdata => 'bstuff',
        },
        { domain => 'adomain.com',
          otherdata => 'astuff',
        });

my @c_ambrus = map { {%{$a[$_]}, %{$b[$_]}} } 0 .. @a - 1;

sub merge_aoh_by_domain {
    my %merge;
    for my $domain_ref ( @_ ) {
        my $to_merge = $merge{$domain_ref->{domain}} ||= {};
        @$to_merge{ keys %$domain_ref } = values %$domain_ref;
    }
    return values %merge;
}

my @c_diotalevi = merge_aoh_by_domain( @a, @b );

Dump(\@c_ambrus, \@c_diotalevi)->Names(q"@c_ambrus", q"@c_diotalevi")-
+>Out;

__END__
[download]

Output:

@c_ambrus = (
              {
                data      => 'adata',
                domain    => 'bdomain.com',
                otherdata => 'bstuff'
              },
              {
                data      => 'bdata',
                domain    => 'adomain.com',
                otherdata => 'astuff'
              }
            );
@c_diotalevi = (
                 {
                   data      => 'adata',
                   domain    => 'adomain.com',
                   otherdata => 'astuff'
                 },
                 {
                   data      => 'bdata',
                   domain    => 'bdomain.com',
                   otherdata => 'bstuff'
                 }
               );
[download]

Comment on Re: combine two AoHs Select or Download Code

Replies are listed 'Best First'.
Re^2: combine two AoHs by alienhuman (Pilgrim) on Mar 07, 2006 at 01:18 UTC
Thanks to all three of you, but in particular ambrus, for demonstrating how the two methods differ. diotalevi gets bonus points for interpreting my poorly articulated question correctly ;-) AH ---------- `Using perl 5.8.1-RC3 unless otherwise noted. Apache/1.3.33 (Darwin) unless otherwise noted. Mac OS X 10.3.9 unless otherwise noted.` [download]	[reply] [d/l]