Probably you want to combine Regexp::Assemble with inplace edit and do something like:

use Regexp::Assemble;
  
my $ra = Regexp::Assemble->new;
$ra->add ($_) for @matchArray;

my $re = $ra->re;

@ARGV = ('filename');
$^I = '.bak';

while (<>) {
  print if m/$re/;
}
[download]

Thanks. If I dont want to use that module then do I do this? instead of that I can have

$full_string = "";
foreach (@match_array) {
  $full_string = $full_string."|".$_;
}
[download]

then do a grep with $fullstring as the match pattern?

If the file is large don't slurp it, use a loop to process a line at a time. You could do it this way:

#open file
#open outFile

while (<file>) {
  my $line = $_;
  my $match = 0;

  for (@matcharray) {
    ($match = 1), last if $line =~ m/$_/;
  }
  print outFile $line if $match;
}
[download]

---

DWIM is Perl's answer to Gödel

#  ... which is same as ...
$full_string = join '|' , @match_array;
[download]

Can we assume that each pattern matches within a single line? If so, then lets have @matcharray an array of qr// expressions, ordered by how often we expect a match - commonest first.

That all means you can read the input file line by line and print that line to an output file if a match is found:

my @matcharray = map {qr/$_/} (
    "all",
    "your",
    "[patterns]",
);

open my $fh, '<', '/path/to/original/file' or die $!;
open my $of, '>', '/path/to/filtered/file' or die $!;

{
    local $_;
    while (<$fh>) {
        for my $pat (@matcharray) {
            /$pat/ and print $of $_ and last;
        }
    }
}
[download]

First of all, use qr// to precompile your patterns:

my @compiled_patterns = map { qx/$_/ } @matcharray;
[download]

Also don't slurp the file into an array. Use something more memory-efficient:

OUTER: while (my $line = <$file>) {
  INNER: for my $pattern (@compiled_patterns) {
    print $line, last INNER if $line =~ $pattern;
  }
}
[download]

Cheers, Flo

Your text says "qr//" but your code says "qx//". Using qx// in this situation could prove very interesting! :-)

my $regex = '(' . join(')|(',@matcharray) . ')';
print "$regex\n";
while(my $line=<>) {
  chomp $line;
  print "$line\n" if($line=~/$regex/);
}
[download]

Cgrep is my reimplementation of grep in perl.