That's because you're reusing the same array each time through the loop. There's only one @doc - the one you declared outside the loop. You push a bunch of references to that array onto the @docs list, but since it's the same @doc, they'll all be the same.

Instead, try one of these idioms. My favourite is to just declare @doc inside your loop:

foreach( @doc_nums ) {
    my @doc;
[download]

Second option: create a copy of the @doc array, and push that on to the list:

    push @docs, [ @doc ];
[download]

Hope that helps :-)

Move my @doc inside the loop so you get a new instance of the doc array each time through. Consider:

use strict;
use warnings;

my @doc_nums = qw(1 2 3 4 5 6 7 8 9);
my @docs;

foreach( @doc_nums ) {
    my @doc;
    
    push @doc, int rand 10 for 1..3;
    push @docs, \@doc;
}

print "@$_\n" for @docs;
[download]

Prints:

9 5 8
9 5 7
2 2 1
3 0 4
8 6 4
6 1 7
6 5 5
8 6 9
9 9 7
[download]

or you could change the reference to a copy:

use strict;
use warnings;

my @doc_nums = qw(1 2 3 4 5 6 7 8 9);
my @docs;
    my @doc;

foreach( @doc_nums ) {
    @doc = ();
    push @doc, int rand 10 for 1..3;
    push @docs, [@doc];
}

print "@$_\n" for @docs;
[download]

    push( @docs, \@doc );

You need push( @docs, [ @doc ] );. The reason is that if you use a backslash, you are taking a reference to the same variable, which contains differents things each time but the reference "points to" the same location in memory. Using square brackets, you create a new reference each time. That's the difference.

Update: To make things clearer, look at this program and its output:

The first time, @d is populated with references to the same information (Data::Dumper shows $VAR1->[0] instead of repeating it). The second example shows different numbers because [ ] create different references each time.

Actually you create a copy each time with the [], and push a reference to the copy.

In the original code the push was creating a new reference each time - to the same instance.

---

DWIM is Perl's answer to Gödel

Perfect! Thanks a ton. For my own edification, do the square brackets actually copy the array *and* make a reference to it in one fell swoop?

The [] makes an anonymous copy of the array and in effect returns an reference to it. {} can be used in similar fashion to create an anonymous copy of a hash.

---

DWIM is Perl's answer to Gödel

Any time you're not sure what's going on with a complex datastructure, I recommend you take a look at it using one (or more) of the techniques outlined here:

How can I visualize my complex data structure?

You might also wish to take a look at:

intro to references
References quick reference

HTH,