Re: Reference Question

push( @docs, \@doc );

You need push( @docs, [ @doc ] );. The reason is that if you use a backslash, you are taking a reference to the same variable, which contains differents things each time but the reference "points to" the same location in memory. Using square brackets, you create a new reference each time. That's the difference.

Update: To make things clearer, look at this program and its output:

use Data::Dumper;
my (@c, @d);

foreach (1..3) {
  @c[0..4] = (rand) x 2;
  push @d, \@c;
}
print Dumper \@d;

@d=();  ## reset @d
foreach (1..3) {
  @c[0..4] = (rand) x 2;
  push @d, [@c];
}
print Dumper \@d;
__END__
$VAR1 = [
          [
            '0.566846394018409',
            '0.566846394018409'
          ],
          $VAR1->[0],
          $VAR1->[0]
        ];
$VAR1 = [
          [
            '0.872105763616624',
            '0.872105763616624'
          ],
          [
            '0.0550789852978433',
            '0.0550789852978433'
          ],
          [
            '0.130973801235072',
            '0.130973801235072'
          ]
        ];
[download]

The first time, @d is populated with references to the same information (Data::Dumper shows $VAR1->[0] instead of repeating it). The second example shows different numbers because [ ] create different references each time.

--
David Serrano

Comment on Re: Reference Question Select or Download Code

Replies are listed 'Best First'.
Re^2: Reference Question by GrandFather (Saint) on Aug 03, 2006 at 21:49 UTC
Actually you create a copy each time with the `[]`, and `push` a reference to the copy. In the original code the `push` was creating a new reference each time - to the same instance. DWIM is Perl's answer to Gödel	[reply] [d/l] [select]
Re^2: Reference Question by caseydentinger (Novice) on Aug 03, 2006 at 21:48 UTC
Perfect! Thanks a ton. For my own edification, do the square brackets actually copy the array and make a reference to it in one fell swoop?	[reply]
Re^3: Reference Question by GrandFather (Saint) on Aug 03, 2006 at 21:54 UTC
The `[]` makes an anonymous copy of the array and in effect returns an reference to it. `{}` can be used in similar fashion to create an anonymous copy of a hash. DWIM is Perl's answer to Gödel	[reply] [d/l] [select]