You should have a look at opendir and readdir. I frequently have code that looks like:

opendir DIRHANDLE, 'directory-name' or die "Can't opendir: $!";
my @plain_files = grep( !/^\./ && -f, readdir( DIRHANDLE ) );
closedir( DIRHANDLE );
[download]

I find it really handy to use grep to pick out the things I want and go from there. If you want to recurse into sub directories and/or do other fancy stuff, have a look at File::Find.

Thanks a lot!

This is an FAQ

#!/usr/bin/perl -w
my @files = <*.pl>;  # get list of .pl files in this dir
my @content;
foreach my $file (@files) {
    if (-f $file && open(FH,"<","$file")) {
        @content= (@content, <FH>);  # add filecontent
        close(FH);
    }
}
# optionally: chomp @content

print "$_" foreach @content;
[download]

When you add each file's lines to @content you are copying the entire array every time around the loop. This could quickly get expensive. It would probably be better to push onto the array, so instead of

@content= (@content, <FH>);
[download]

you could do

push @content, <FH>;
[download]

I ran a benchmark of these two methods on a sample of 65 scripts totalling 2082 lines, "Copy" being your original and "Push" my suggested alternative. Here's the benchmark code

Read more... (1041 Bytes)

and here's the result

       Rate  Copy  Push
Copy 2.32/s    --  -94%
Push 41.9/s 1710%    --
[download]

As you can see, copying the array each time takes a lot of resources.

Cheers,

JohnGG

Most of the time, I tend to prefer glob to opendir followed by readdir, but that's mostly stylistic.

For glob, you would do something vaguely like:

my @list = glob('*');
[download]

I believe glob ignores hidden files (on *ix, files with names starting with "."), while readdir doesn't. With readdir, you'll always get at least two files, as . (the directory itself) and .. (its parent) will (almost) always show up (offhand, I don't know if .. will show up for the root directory on *ix), so you'll have to handle these if you're going to recurse through a directory tree, a la find.

> I believe glob ignores hidden files (on *ix, files with names starting with "."),
> while readdir doesn't.

It depends on how you call glob:
In a directory containing the files aaaa, bbbb, cccc, .dddd, .eeee, .ffff

glob (and similar '<>'):

$ perl -e "print '-> ', join '|', glob('*');"
-> aaaa|bbbb|cccc

$ perl -e "print '-> ', join '|', glob('.*');"
-> .|..|.dddd|.eeee|.ffff

$ perl -e "print '-> ', join '|', glob('* .*');"
-> aaaa|bbbb|cccc|.|..|.dddd|.eeee|.ffff
[download]

readdir:

$ perl -e "opendir DIR, '.'; print '->', join '|', readdir(DIR);"
->.|..|aaaa|bbbb|cccc|.dddd|.eeee|.ffff
[download]


klekker