in reply to Re: Read from directory list...
in thread Read from directory list...

When you add each file's lines to @content you are copying the entire array every time around the loop. This could quickly get expensive. It would probably be better to push onto the array, so instead of

@content= (@content, <FH>);

[download]

you could do

push @content, <FH>;

[download]

I ran a benchmark of these two methods on a sample of 65 scripts totalling 2082 lines, "Copy" being your original and "Push" my suggested alternative. Here's the benchmark code

use strict;
use warnings;

use Benchmark q{cmpthese};

my @files = grep { -f } <spw59*>;

my $rcCopy = sub
   {
       my @content = ();
       foreach my $file ( @files )
       {
           open my $fh, q{<}, $file
              or die qq{open: $file: $!\n};
           @content = (@content, <$fh>);
           close $fh
              or die qq{close: $file: $!\n};
       }
       
       return \@content;
   };

my $rcPush = sub
   {
       my @content = ();
       foreach my $file ( @files )
       {
           open my $fh, q{<}, $file
              or die qq{open: $file: $!\n};
           push @content, <$fh>;
           close $fh
              or die qq{close: $file: $!\n};
       }
       
       return \@content;
   };

cmpthese (-60,
   {
      Copy => $rcCopy,
      Push => $rcPush,
   });

[download]

and here's the result

       Rate  Copy  Push
Copy 2.32/s    --  -94%
Push 41.9/s 1710%    --

[download]

As you can see, copying the array each time takes a lot of resources.

Cheers,

JohnGG

In Section Seekers of Perl Wisdom