See Sorting An Array of Versions.

If no individual element of the 'numbers' is > 255

$/ = "\n";;
print for map{ 
    join '.', unpack 'C*', $_ 
} sort map{ 
    pack 'C*', split '\.'
} qw[1.1 11.2.3 2.3 11.2.1];;

1.1
2.3
11.2.1
11.2.3
[download]

Update: In fact, utilising Unicode, this can handle individual number elements upto >64,000. Which ought to be enough as it would allow a 3-part version number to handle 1 new version every microsecond for a project life exceeding 8 years before it encountered problems.

print for map{ 
    join'.',unpack'U*',$_ 
} sort map{ 
    pack'U*',split '\.', "1.2.$_.4" 
} reverse qw[ 1 11 111 127 127 128 129 254 255 256 257 1111 11111 6400
+0 ];;
1.2.1.4
1.2.11.4
1.2.111.4
1.2.127.4
1.2.127.4
1.2.128.4
1.2.129.4
1.2.254.4
1.2.255.4
1.2.256.4
1.2.257.4
1.2.1111.4
1.2.11111.4
1.2.64000.4
[download]

And just to clarify, perl's sort routine does not only do numeric or string sorting. It sorts based on any arbitrary criteria you choose as long as you're willing to write a binary tri-state comparator that has the same semantics as  <=> or cmp (i.e., returns -1 for less then, 0 for equal and 1 for greater than)

use Sort::Key::OID qw(oidsort);
my @sorted = oidsort @data;
[download]

The search for natural sort turns up lots of ways to do this type of thing.

#!/usr/bin/perl
use strict;use warnings;

sub versionsort {
   my ($a,$b) = @_;
   my $diff;
   foreach (0..$#$a) {
      return 1 if !defined $b->[$_];
      $diff = $a->[$_] <=> $b->[$_];
      return $diff if $diff;
      }
   return @$a <=> @$b;
   }

my @data = qw(1.1 11.2.3 2.3 11.2.1 11.2 11.2.1.1);
print "before: ".join(', ',@data)."\n";
my @versions = map { [split '\.',$_] } @data;
my @sorted = map { join '.',@$_}
                 sort {versionsort($a,$b)} @versions;
print "sorted: ".join(', ',@sorted)."\n";
[download]

before: 1.1, 11.2.3, 2.3, 11.2.1, 11.2, 11.2.1.1
sorted: 1.1, 2.3, 11.2, 11.2.1, 11.2.1.1, 11.2.3
[download]